source: branches/gsoc09-logging/base/aclocal.m4 @ 143448

Last change on this file since 143448 was 59527, checked in by blb@…, 10 years ago

Merge from trunk (may be a few missed bits to be picked up later)

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 25.5 KB
Line 
1dnl $Id: aclocal.m4 59527 2009-10-16 05:29:39Z blb@macports.org $
2builtin(include,m4/tcl.m4)
3builtin(include,m4/pthread.m4)
4builtin(include,m4/foundation.m4)
5
6#------------------------------------------------------------------------
7# MP_CHECK_FRAMEWORK_COREFOUNDATION --
8#
9#       Check if CoreFoundation framework is available, define HAVE_FRAMEWORK_COREFOUNDATION if so.
10#
11# Arguments:
12#       None.
13#
14# Requires:
15#       None.
16#
17# Depends:
18#               AC_LANG_PROGRAM
19#
20# Results:
21#       Result is cached.
22#
23#       If CoreFoundation framework is available, defines the following variables:
24#               HAVE_FRAMEWORK_COREFOUNDATION
25#
26#------------------------------------------------------------------------
27AC_DEFUN(MP_CHECK_FRAMEWORK_COREFOUNDATION, [
28        FRAMEWORK_LIBS="-framework CoreFoundation"
29
30        AC_MSG_CHECKING([for CoreFoundation framework])
31
32        AC_CACHE_VAL(mp_cv_have_framework_corefoundation, [
33                ac_save_LIBS="$LIBS"
34                LIBS="$FRAMEWORK_LIBS $LIBS"
35               
36                AC_LINK_IFELSE([
37                        AC_LANG_PROGRAM([
38                                        #include <CoreFoundation/CoreFoundation.h>
39                                ], [
40                                        CFURLRef url = CFURLCreateWithFileSystemPath(NULL, CFSTR("/testing"), kCFURLPOSIXPathStyle, 1);
41                                        CFArrayRef bundles = CFBundleCreateBundlesFromDirectory(NULL, url, CFSTR("pkg"));
42                        ])
43                        ], [
44                                mp_cv_have_framework_corefoundation="yes"
45                        ], [
46                                mp_cv_have_framework_corefoundation="no"
47                        ]
48                )
49
50                LIBS="$ac_save_LIBS"
51        ])
52
53        AC_MSG_RESULT(${mp_cv_have_framework_corefoundation})
54
55        if test x"${mp_cv_have_framework_corefoundation}" = "xyes"; then
56                AC_DEFINE([HAVE_FRAMEWORK_COREFOUNDATION], [], [Define if CoreFoundation framework is available])
57        fi
58
59        AC_SUBST(HAVE_FRAMEWORK_COREFOUNDATION)
60])
61
62
63#------------------------------------------------------------------------
64# MP_CHECK_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER --
65#
66#       Check if if the routine CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER
67#       is available in CoreFoundation.
68#
69# Arguments:
70#       None.
71#
72# Requires:
73#       None.
74#
75# Depends:
76#               AC_LANG_PROGRAM
77#
78# Results:
79#       Result is cached.
80#
81#       If function CFNotificationCenterGetDarwinNotifyCenter is in the CoreFoundation framework, defines the following variables:
82#               HAVE_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER
83#
84#------------------------------------------------------------------------
85AC_DEFUN(MP_CHECK_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER, [
86        FRAMEWORK_LIBS="-framework CoreFoundation"
87
88        AC_MSG_CHECKING([for CFNotificationCenterGetDarwinNotifyCenter])
89
90        AC_CACHE_VAL(mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter, [
91                ac_save_LIBS="$LIBS"
92                LIBS="$FRAMEWORK_LIBS $LIBS"
93               
94                AC_LINK_IFELSE([
95                        AC_LANG_PROGRAM([
96                                        #include <CoreFoundation/CoreFoundation.h>
97                                ], [
98                                        CFNotificationCenterRef ref = CFNotificationCenterGetDarwinNotifyCenter();
99                        ])
100                        ], [
101                                mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter="yes"
102                        ], [
103                                mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter="no"
104                        ]
105                )
106
107                LIBS="$ac_save_LIBS"
108        ])
109
110        AC_MSG_RESULT(${mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter})
111
112        if test x"${mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter}" = "xyes"; then
113                AC_DEFINE([HAVE_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER], [], [Define if function CFNotificationCenterGetDarwinNotifyCenter in CoreFoundation framework])
114        fi
115
116        AC_SUBST(HAVE_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER)
117])
118
119
120#------------------------------------------------------------------------
121# MP_CHECK_FRAMEWORK_SYSTEMCONFIGURATION --
122#
123#       Check if SystemConfiguration framework is available, define HAVE_FRAMEWORK_SYSTEMCONFIGURATION if so.
124#
125# Arguments:
126#       None.
127#
128# Requires:
129#       None.
130#
131# Depends:
132#               AC_LANG_PROGRAM
133#
134# Results:
135#       Result is cached.
136#
137#       If SystemConfiguration framework is available, defines the following variables:
138#               HAVE_FRAMEWORK_SYSTEMCONFIGURATION
139#
140#------------------------------------------------------------------------
141AC_DEFUN(MP_CHECK_FRAMEWORK_SYSTEMCONFIGURATION, [
142        FRAMEWORK_LIBS="-framework SystemConfiguration"
143
144        AC_MSG_CHECKING([for SystemConfiguration framework])
145
146        AC_CACHE_VAL(mp_cv_have_framework_systemconfiguration, [
147                ac_save_LIBS="$LIBS"
148                LIBS="$FRAMEWORK_LIBS $LIBS"
149               
150                AC_LINK_IFELSE([
151                        AC_LANG_PROGRAM([
152                                        #include <SystemConfiguration/SystemConfiguration.h>
153                                ], [
154                                        int err = SCError();
155                                        SCDynamicStoreRef dsRef = SCDynamicStoreCreate(NULL, NULL, NULL, NULL);
156                        ])
157                        ], [
158                                mp_cv_have_framework_systemconfiguration="yes"
159                        ], [
160                                mp_cv_have_framework_systemconfiguration="no"
161                        ]
162                )
163
164                LIBS="$ac_save_LIBS"
165        ])
166
167        AC_MSG_RESULT(${mp_cv_have_framework_systemconfiguration})
168
169        if test x"${mp_cv_have_framework_systemconfiguration}" = "xyes"; then
170                AC_DEFINE([HAVE_FRAMEWORK_SYSTEMCONFIGURATION], [], [Define if SystemConfiguration framework is available])
171        fi
172
173        AC_SUBST(HAVE_FRAMEWORK_SYSTEMCONFIGURATION)
174])
175
176
177#------------------------------------------------------------------------
178# MP_CHECK_FRAMEWORK_IOKIT --
179#
180#       Check if IOKit framework is available, define HAVE_FRAMEWORK_IOKIT if so.
181#
182# Arguments:
183#       None.
184#
185# Requires:
186#       None.
187#
188# Depends:
189#               AC_LANG_PROGRAM
190#
191# Results:
192#       Result is cached.
193#
194#       If IOKit framework is available, defines the following variables:
195#               HAVE_FRAMEWORK_IOKIT
196#
197#------------------------------------------------------------------------
198AC_DEFUN(MP_CHECK_FRAMEWORK_IOKIT, [
199        FRAMEWORK_LIBS="-framework IOKit"
200
201        AC_MSG_CHECKING([for IOKit framework])
202
203        AC_CACHE_VAL(mp_cv_have_framework_iokit, [
204                ac_save_LIBS="$LIBS"
205                LIBS="$FRAMEWORK_LIBS $LIBS"
206               
207                AC_LINK_IFELSE([
208                        AC_LANG_PROGRAM([
209                                        #include <IOKit/IOKitLib.h>
210                                ], [
211                                        IOCreateReceivePort(0, NULL);
212                                        IORegisterForSystemPower(0, NULL, NULL, NULL);
213                        ])
214                        ], [
215                                mp_cv_have_framework_iokit="yes"
216                        ], [
217                                mp_cv_have_framework_iokit="no"
218                        ]
219                )
220
221                LIBS="$ac_save_LIBS"
222        ])
223
224        AC_MSG_RESULT(${mp_cv_have_framework_iokit})
225
226        if test x"${mp_cv_have_framework_iokit}" = "xyes"; then
227                AC_DEFINE([HAVE_FRAMEWORK_IOKIT], [], [Define if IOKit framework is available])
228        fi
229
230        AC_SUBST(HAVE_FRAMEWORK_IOKIT)
231])
232
233
234dnl This macro checks if the user specified a ports tree
235dnl explicitly. If not, search for it
236
237# MP_PATH_PORTSDIR(DEFAULT_PORTSDIR)
238#---------------------------------------
239 AC_DEFUN([MP_PATH_PORTSDIR],[
240        dnl For ease of reading, run after gcc has been found/configured
241        AC_REQUIRE([AC_PROG_CC])
242
243        AC_ARG_WITH(ports-dir, [AS_HELP_STRING([--with-ports-dir=DIR],[Specify alternate ports directory])], [ portsdir="$withval" ] )
244
245
246        AC_MSG_CHECKING([for ports tree])
247        if test "x$portsdir" != "x" ; then
248          if test -d "$portsdir" -a -e "$portsdir/PortIndex" ; then
249                :
250          else
251                AC_MSG_ERROR([$portsdir not a valid ports tree])
252          fi
253        else
254                dnl If the user didn't give a path, look for default
255                if test "x$1" != "x" ; then
256                  if test -d "$1" -a -e "$1/PortIndex" ; then
257                        portsdir=$1
258                  fi
259                fi
260        fi
261
262        if test "x$portsdir" != "x" ; then
263                AC_MSG_RESULT($portsdir)
264                PORTSDIR="$portsdir"
265                AC_SUBST(PORTSDIR)
266        else
267                AC_MSG_WARN([No ports tree found])
268        fi
269
270         ])
271
272
273# MP_PATH_MPCONFIGDIR
274#---------------------------------------
275AC_DEFUN([MP_PATH_MPCONFIGDIR],[
276        dnl if the user actually specified --prefix, shift
277        dnl mpconfigdir to $prefix/etc/macports
278        dnl     AC_REQUIRE([MP_PATH_PORTSDIR])
279       
280        AC_MSG_CHECKING([for MacPorts config directory])
281
282        mpconfigdir='${sysconfdir}/macports'
283
284        AC_MSG_RESULT([$mpconfigdir])
285        MPCONFIGDIR="$mpconfigdir"
286        AC_SUBST(MPCONFIGDIR)
287
288        ])
289
290# MP_CHECK_OLDLAYOUT
291#---------------------------------------
292AC_DEFUN([MP_CHECK_OLDLAYOUT],[
293        dnl Bail if there is an existing install of DP/MP older than 1.5
294
295        AC_MSG_CHECKING([that any existing MacPorts install can be upgraded])
296
297        eval dpversionfile="${sysconfdir}/ports/dp_version"
298        if test -f $dpversionfile; then
299                AC_MSG_ERROR([Existing MacPorts or DarwinPorts install is too old to be upgraded. Install MacPorts 1.7.1 first.])
300        else
301                AC_MSG_RESULT([yes])
302        fi
303
304        ])
305
306# MP_CHECK_NOROOTPRIVILEGES
307#-------------------------------------------------
308AC_DEFUN([MP_CHECK_NOROOTPRIVILEGES],[
309        dnl if with user specifies --with-no-root-privileges,
310        dnl use current user and group.
311        dnl use ~/Library/Tcl as Tcl package directory
312                AC_REQUIRE([MP_PATH_MPCONFIGDIR])
313
314        AC_ARG_WITH(no-root-privileges, [AS_HELP_STRING([--with-no-root-privileges],[Specify that MacPorts should be installed in your home directory])], [ROOTPRIVS=$withval] )
315
316        if test "${ROOTPRIVS+set}" = set; then
317
318                # Set install-user to current user
319                AC_MSG_CHECKING([for install user])
320                DSTUSR=`id -un`
321                AC_MSG_RESULT([$DSTUSR])
322                AC_SUBST(DSTUSR)
323               
324                # Set install-group to current user
325                AC_MSG_CHECKING([for install group])
326                DSTGRP=`id -gn`
327                AC_MSG_RESULT([$DSTGRP])
328                AC_SUBST(DSTGRP)
329
330                # Set Tcl package directory to ~/Library/Tcl
331            AC_MSG_CHECKING(for Tcl package directory)
332                ac_cv_c_tclpkgd="~$DSTUSR/Library/Tcl"
333            # Convert to a native path and substitute into the output files.
334            PACKAGE_DIR_NATIVE=`${CYGPATH} ${ac_cv_c_tclpkgd}`
335            TCL_PACKAGE_DIR=${PACKAGE_DIR_NATIVE}
336            AC_SUBST(TCL_PACKAGE_DIR)
337                if test x"${ac_cv_c_tclpkgd}" = x ; then
338                        AC_MSG_ERROR(Tcl package directory not found.  Please specify its location with --with-tclpackage)
339            else
340                        AC_MSG_RESULT(${ac_cv_c_tclpkgd})
341            fi
342        fi
343
344])
345
346# MP_CHECK_RUNUSER
347#-------------------------------------------------
348AC_DEFUN([MP_CHECK_RUNUSER],[
349        dnl if with user specifies --with-macports-user,
350        dnl use it. otherwise default to platform defaults
351       AC_REQUIRE([MP_PATH_MPCONFIGDIR])
352
353        AC_ARG_WITH(macports-user, [AS_HELP_STRING([--with-macports-user=USER],[Specify user to drop privileges to, if possible, during compiles etc.])], [ RUNUSR=$withval ] )
354       
355        AC_MSG_CHECKING([for macports user])
356        if test "x$RUNUSR" = "x" ; then
357# dropping root privs is still buggy
358#          RUNUSR=`id -un`
359           RUNUSR=root
360        fi
361
362        AC_MSG_RESULT([$RUNUSR])
363        AC_SUBST(RUNUSR)
364])
365
366
367# MP_SHARED_DIRECTORY
368#-------------------------------------------------
369AC_DEFUN([MP_SHARED_DIRECTORY],[
370        dnl if with user specifies --with-shared-directory,
371        dnl use 0775 permissions for ${prefix} directories
372        AC_REQUIRE([MP_PATH_MPCONFIGDIR])
373
374        AC_ARG_WITH(shared-directory, [AS_HELP_STRING([--with-shared-directory],[Use 0775 permissions for installed directories])], [ SHAREDIR=$withval ] )
375
376        if test "${SHAREDIR+set}" = set; then   
377                AC_MSG_CHECKING([whether to share the install directory with all members of the install group])
378            DSTMODE=0775
379
380                AC_MSG_RESULT([$DSTMODE])
381                AC_SUBST(DSTMODE)
382        fi
383])
384
385# MP_CHECK_INSTALLUSER
386#-------------------------------------------------
387AC_DEFUN([MP_CHECK_INSTALLUSER],[
388        dnl if with user specifies --with-install-user,
389        dnl use it. otherwise default to platform defaults
390        AC_REQUIRE([MP_PATH_MPCONFIGDIR])
391
392        AC_ARG_WITH(install-user, [AS_HELP_STRING([--with-install-user=USER],[Specify user ownership of installed files])], [ DSTUSR=$withval ] )
393       
394        AC_MSG_CHECKING([for install user])
395        if test "x$DSTUSR" = "x" ; then
396           DSTUSR=root
397        fi
398
399        AC_MSG_RESULT([$DSTUSR])
400        AC_SUBST(DSTUSR)
401])
402
403# MP_CHECK_INSTALLGROUP
404#-------------------------------------------------
405AC_DEFUN([MP_CHECK_INSTALLGROUP],[
406        dnl if with user specifies --with-install-group,
407        dnl use it. otherwise default to platform defaults
408        AC_REQUIRE([MP_CHECK_INSTALLUSER])
409
410        AC_ARG_WITH(install-group, [AS_HELP_STRING([--with-install-group=GROUP],[Specify group ownership of installed files])], [ DSTGRP=$withval ] )
411
412        AC_MSG_CHECKING([for install group])
413        if test "x$DSTGRP" = "x" ; then
414           
415           case $host_os in
416           darwin*)
417                DSTGRP="admin"
418                ;;
419           freebsd*)
420                DSTGRP="wheel"
421                ;;
422           linux*)
423                DSTGRP="root"
424                ;;
425           *)
426                DSTGRP="wheel"
427                ;;
428           esac
429        fi
430
431        AC_MSG_RESULT([$DSTGRP])
432        AC_SUBST(DSTGRP)
433])
434
435# MP_DIRECTORY_MODE
436#-------------------------------------------------
437AC_DEFUN([MP_DIRECTORY_MODE],[
438        dnl if with user specifies --with-directory-mode,
439        dnl use the specified permissions for ${prefix} directories
440        dnl otherwise use 0755
441        AC_REQUIRE([MP_PATH_MPCONFIGDIR])
442
443        AC_ARG_WITH(directory-mode, [AS_HELP_STRING([--with-directory-mode=MODE],[Specify directory mode of installed directories])], [ DSTMODE=$withval ] )
444       
445        AC_MSG_CHECKING([what permissions to use for installation directories])
446        if test "x$DSTMODE" = "x" ; then
447           DSTMODE=0755
448        fi
449
450        AC_MSG_RESULT([$DSTMODE])
451        AC_SUBST(DSTMODE)
452])
453
454# MP_PATH_APPLICATIONS
455#---------------------------------------
456AC_DEFUN([MP_PATH_APPLICATIONS],[
457        AC_REQUIRE([MP_CHECK_INSTALLUSER])
458
459    AC_ARG_WITH(applications-dir,[AS_HELP_STRING([--with-applications-dir],[Applications installation directory.])], MPAPPLICATIONSDIR=${withval})
460
461    oldprefix=$prefix
462    if test "x$prefix" = "xNONE" ; then
463        prefix=$ac_default_prefix
464    fi
465    AC_MSG_CHECKING([for Applications installation directory])
466
467        if test "x$MPAPPLICATIONSDIR" = "x" ; then
468            if test "$DSTUSR" = "root" ; then
469                MPAPPLICATIONSDIR="/Applications/MacPorts"
470            else
471                MPAPPLICATIONSDIR="$(eval echo ~$DSTUSR)/Applications/MacPorts"
472            fi
473        fi
474
475        AC_MSG_RESULT([$MPAPPLICATIONSDIR])
476    AC_SUBST(MPAPPLICATIONSDIR)
477    prefix=$oldprefix
478])
479
480# MP_PATH_FRAMEWORKS
481#---------------------------------------
482AC_DEFUN([MP_PATH_FRAMEWORKS],[
483        AC_REQUIRE([MP_CHECK_INSTALLUSER])
484
485    AC_ARG_WITH(frameworks-dir,[AS_HELP_STRING([--with-frameworks-dir],[Frameworks installation directory.])], MPFRAMEWORKSDIR=${withval})
486
487    oldprefix=$prefix
488    if test "x$prefix" = "xNONE" ; then
489        prefix=$ac_default_prefix
490    fi
491    AC_MSG_CHECKING([for Frameworks installation directory])
492
493        if test "x$MPFRAMEWORKSDIR" = "x" ; then
494                MPFRAMEWORKSDIR="${prefix}/Library/Frameworks"
495        fi
496
497        AC_MSG_RESULT([$MPFRAMEWORKSDIR])
498    AC_SUBST(MPFRAMEWORKSDIR)
499    prefix=$oldprefix
500])
501
502
503# MP_UNIVERSAL_OPTIONS
504#---------------------------------------
505AC_DEFUN([MP_UNIVERSAL_OPTIONS],[
506  AC_ARG_WITH(universal-archs,[AS_HELP_STRING([--with-universal-archs="CPU"],[Universal CPU architectures (space separated)])], UNIVERSAL_ARCHS=${withval})
507
508  if test "x$UNIVERSAL_ARCHS" = "x"; then
509    case "$MACOSX_VERSION" in
510      10.[[0-5]]*)
511        UNIVERSAL_ARCHS="i386 ppc"
512        ;;
513      *)
514        UNIVERSAL_ARCHS="x86_64 i386"
515        ;;
516    esac
517  fi
518
519  AC_MSG_CHECKING([for Universal CPU architectures])
520  AC_MSG_RESULT([$UNIVERSAL_ARCHS])
521  AC_SUBST(UNIVERSAL_ARCHS)
522])
523
524# MP_LIB_MD5
525#---------------------------------------
526# Check for an md5 implementation
527AC_DEFUN([MP_LIB_MD5],[
528
529        # Check for libmd, which is prefered
530        AC_CHECK_LIB([md], [MD5Update],[
531                AC_CHECK_HEADERS([md5.h], ,[
532                        case $host_os in
533                                darwin*)       
534                                        AC_MSG_NOTICE([Please install the BSD SDK package from the Xcode Developer Tools CD.])
535                                        ;;
536                                *)     
537                                        AC_MSG_NOTICE([Please install the libmd developer headers for your platform.])
538                                        ;;
539                        esac
540                        AC_MSG_ERROR([libmd was found, but md5.h is missing.])
541                ])
542                AC_DEFINE([HAVE_LIBMD], ,[Define if you have the `md' library (-lmd).])
543                MD5_LIBS="-lmd"]
544        )
545        if test "x$MD5_LIBS" = "x"; then
546                AC_MSG_ERROR([Neither CommonCrypto nor libmd were found. A working md5 implementation is required.])
547        fi
548        AC_SUBST([MD5_LIBS])
549])
550
551# MP_PROG_DAEMONDO
552#---------------------------------------
553AC_DEFUN([MP_PROG_DAEMONDO],[
554        AC_REQUIRE([MP_CHECK_FRAMEWORK_COREFOUNDATION])
555        AC_REQUIRE([MP_CHECK_FRAMEWORK_SYSTEMCONFIGURATION])
556        AC_REQUIRE([MP_CHECK_FRAMEWORK_IOKIT])
557        AC_REQUIRE([MP_CHECK_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER])
558       
559    AC_MSG_CHECKING(for whether we will build daemondo)
560    result=no
561        case $host_os in
562        darwin*)
563                if test "x$mp_cv_have_framework_corefoundation" == "xyes" &&
564                   test "x$mp_cv_have_framework_systemconfiguration" == "xyes" &&
565                   test "x$mp_cv_have_framework_iokit" == "xyes" &&
566                   test "x$mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter" == "xyes"; then
567                        result=yes
568                        EXTRA_PROGS="$EXTRA_PROGS daemondo"
569                        AC_CONFIG_FILES([src/programs/daemondo/Makefile])
570                fi
571                ;;
572        *)
573        esac
574        AC_MSG_RESULT(${result})
575])
576
577#------------------------------------------------------------------------
578# MP_TCL_PACKAGE_DIR --
579#
580#       Locate the correct directory for Tcl package installation
581#
582# Arguments:
583#       None.
584#
585# Requires:
586#       TCLVERSION must be set
587#       CYGPATH must be set
588#       TCLSH must be set
589#
590# Results:
591#
592#       Adds a --with-tclpackage switch to configure.
593#       Result is cached.
594#
595#       Substs the following vars:
596#               TCL_PACKAGE_DIR
597#------------------------------------------------------------------------
598
599AC_DEFUN(MP_TCL_PACKAGE_DIR, [
600        AC_REQUIRE([MP_CHECK_INSTALLUSER])
601
602    AC_MSG_CHECKING(for Tcl package directory)
603
604    AC_ARG_WITH(tclpackage, [  --with-tclpackage       Tcl package installation directory.], with_tclpackagedir=${withval})
605
606    if test x"${with_tclpackagedir}" != x ; then
607        ac_cv_c_tclpkgd=${with_tclpackagedir}
608    else
609        AC_CACHE_VAL(ac_cv_c_tclpkgd, [
610            # Use the value from --with-tclpackage, if it was given
611
612            if test x"${with_tclpackagedir}" != x ; then
613                echo "tclpackagedir"
614                ac_cv_c_tclpkgd=${with_tclpackagedir}
615            else
616                # On darwin we can do some intelligent guessing
617                case $host_os in
618                    darwin*)
619                        tcl_autopath=`echo 'puts -nonewline \$auto_path' | $TCLSH`
620                        for path in $tcl_autopath; do
621                        if test "$DSTUSR" = "root" ; then
622                            if test "$path" = "/Library/Tcl"; then
623                                ac_cv_c_tclpkgd="$path"
624                                break
625                            fi
626                            if test "$path" = "/System/Library/Tcl"; then
627                                if test -d "$path"; then
628                                    ac_cv_c_tclpkgd="$path"
629                                    break
630                                fi
631                            fi
632                        elif test "$path" = "~/Library/Tcl"; then
633                            ac_cv_c_tclpkgd="~$DSTUSR/Library/Tcl"
634                            break
635                        fi
636                        done
637                    ;;
638                esac
639                if test x"${ac_cv_c_tclpkgd}" = x ; then
640                    # Fudge a path from the first entry in the auto_path
641                    tcl_pkgpath=`echo 'puts -nonewline [[lindex \$auto_path 0]]' | $TCLSH`
642                    if test -d "$tcl_pkgpath"; then
643                        ac_cv_c_tclpkgd="$tcl_pkgpath"
644                    fi
645                    # If the first entry does not exist, do nothing
646                fi
647            fi
648        ])
649    fi
650
651    if test x"${ac_cv_c_tclpkgd}" = x ; then
652        AC_MSG_ERROR(Tcl package directory not found.  Please specify its location with --with-tclpackage)
653    else
654        AC_MSG_RESULT(${ac_cv_c_tclpkgd})
655    fi
656
657    # Convert to a native path and substitute into the output files.
658
659    PACKAGE_DIR_NATIVE=`${CYGPATH} ${ac_cv_c_tclpkgd}`
660
661    TCL_PACKAGE_DIR=${PACKAGE_DIR_NATIVE}
662
663    AC_SUBST(TCL_PACKAGE_DIR)
664])
665
666# MP_PROG_TCLSH
667#---------------------------------------
668AC_DEFUN([MP_PROG_TCLSH],[
669
670
671        case $host_os in
672                freebsd*)
673                        # FreeBSD installs a dummy tclsh (annoying)
674                        # Look for a real versioned tclsh with threads first
675                        # Look for a real versioned tclsh without threads second
676                        AC_PATH_PROG([TCLSH], [tclsh${TCL_VERSION}-threads tclsh${TCL_VERSION} tclsh])
677                        ;;
678                *)
679                        # Otherwise, look for a non-versioned tclsh
680                        AC_PATH_PROG([TCLSH], [tclsh tclsh${TCL_VERSION}])
681                        ;;
682        esac
683        if test "x$TCLSH" = "x" ; then
684                AC_MSG_ERROR([Could not find tclsh])
685        fi
686
687        AC_SUBST(TCLSH)
688])
689
690# MP_TCL_PACKAGE
691#       Determine if a Tcl package is present.
692#
693# Arguments:
694#       Package name (may include the version)
695#
696# Syntax:
697#   MP_TCL_PACKAGE (package, [action-if-found], [action-if-not-found])
698#
699# Requires:
700#       TCLSH must be set
701#
702# Results:
703#       Execute action-if-found or action-if-not-found
704#---------------------------------------
705AC_DEFUN([MP_TCL_PACKAGE],[
706        AC_MSG_CHECKING([for Tcl $1 package])
707        package_present=`echo 'if {[[catch {package require $1}]]} {puts -nonewline 0} else {puts -nonewline 1}' | $TCLSH`
708        AS_IF([test "$package_present" = "1"], [$2], [$3])[]
709])
710
711# MP_TCL_THREAD_SUPPORT
712#       Determine if thread support is available in tclsh.
713#
714# Arguments:
715#       None.
716#
717# Requires:
718#       TCLSH must be set
719#
720# Results:
721#   Fails if thread support isn't available.
722#---------------------------------------
723AC_DEFUN([MP_TCL_THREAD_SUPPORT],[
724        AC_MSG_CHECKING([whether tclsh was compiled with threads])
725        tcl_threadenabled=`echo 'puts -nonewline [[info exists tcl_platform(threaded)]]' | $TCLSH`
726        if test "$tcl_threadenabled" = "1" ; then
727                AC_MSG_RESULT([yes])
728        else
729                AC_MSG_RESULT([no])
730                AC_MSG_ERROR([tcl wasn't compiled with threads enabled])
731        fi
732])
733
734# MP_LIBCURL_FLAGS
735#       Sets the flags to compile with libcurl.
736#
737# Arguments:
738#       None.
739#
740# Requires:
741#   curl-config or user parameters to define the flags.
742#
743# Results:
744#   defines some help strings.
745#   sets CFLAGS_LIBCURL and LDFLAGS_LIBCURL
746#---------------------------------------
747AC_DEFUN([MP_LIBCURL_FLAGS],[
748        AC_ARG_WITH(curlprefix,
749                   [  --with-curlprefix       base directory for the cURL install '/usr', '/usr/local',...],
750                   [  curlprefix=$withval ])
751
752        if test "x$curlprefix" = "x"; then
753                AC_PATH_PROG([CURL_CONFIG], [curl-config])
754        else
755                AC_PATH_PROG([CURL_CONFIG], [curl-config], , [$curlprefix/bin])
756        fi
757
758        if test "x$CURL_CONFIG" = "x"; then
759                AC_MSG_ERROR([cannot find curl-config. Is libcurl installed?])
760        fi
761
762        CFLAGS_LIBCURL=$($CURL_CONFIG --cflags)
763        if test "x$curlprefix" = "x"; then
764                # System curl-config emits absurd output for --libs
765                # See rdar://7244457
766                LDFLAGS_LIBCURL="-lcurl"
767        else
768                # Due to a bug in dist, --arch flags are improperly supplied by curl-config.
769                # Get rid of them.
770                LDFLAGS_LIBCURL=$($CURL_CONFIG --libs | [sed 's/-arch [A-Za-z0-9_]* //g'])
771        fi
772
773        AC_SUBST(CFLAGS_LIBCURL)
774        AC_SUBST(LDFLAGS_LIBCURL)
775])
776
777dnl This macro tests if the compiler supports GCC's
778dnl __attribute__ syntax for unused variables/parameters
779AC_DEFUN([MP_COMPILER_ATTRIBUTE_UNUSED], [
780        AC_MSG_CHECKING([how to mark unused variables])
781        AC_COMPILE_IFELSE(
782                [AC_LANG_SOURCE([[int a __attribute__ ((unused));]])],
783                [AC_DEFINE(UNUSED, [__attribute__((unused))], [Attribute to mark unused variables])],
784                [AC_DEFINE(UNUSED, [])])
785
786        AC_MSG_RESULT([])
787       
788])
789
790dnl This macro ensures MP installation prefix bin/sbin paths are NOT in PATH
791dnl for configure to prevent potential problems when base/ code is updated
792dnl and ports are installed that would match needed items.
793AC_DEFUN([MP_PATH_SCAN],[
794        oldprefix=$prefix
795        if test "x$prefix" = "xNONE" ; then
796                prefix=$ac_default_prefix
797        fi
798        oldPATH=$PATH
799        newPATH=
800        as_save_IFS=$IFS; IFS=$PATH_SEPARATOR
801        for as_dir in $oldPATH
802        do
803                IFS=$as_save_IFS
804                if test "x$as_dir" != "x$prefix/bin" &&
805                        test "x$as_dir" != "x$prefix/sbin"; then
806                        if test -z "$newPATH"; then
807                                newPATH=$as_dir
808                        else
809                                newPATH=$newPATH$PATH_SEPARATOR$as_dir
810                        fi
811                fi
812        done
813        PATH=$newPATH; export PATH
814        AC_SUBST(PATH_CLEANED,$newPATH)
815        prefix=$oldprefix
816])
817
818dnl This macro tests for sed support of -E (BSD) or -r (GNU)
819AC_DEFUN([MP_SED_EXTENDED_REGEXP],[
820        AC_PATH_PROG(SED, [sed])
821
822        if test "x$SED" = "x"; then
823                AC_MSG_ERROR([cannot find sed. Is sed installed?])
824        fi
825
826        AC_MSG_CHECKING([which sed flag to use for extended regexp])
827        [any_sed_flag=`echo foo | $SED    -e s/foo+/OK/ 2>&1 | grep OK`]
828        [bsd_sed_flag=`echo foo | $SED -E -e s/foo+/OK/ 2>&1 | grep OK`]
829        [gnu_sed_flag=`echo foo | $SED -r -e s/foo+/OK/ 2>&1 | grep OK`]
830        if test "x$any_sed_flag" = "xOK" ; then
831                AC_MSG_RESULT([none])
832                SED_EXT=
833        elif test "x$bsd_sed_flag" = "xOK" ; then
834                AC_MSG_RESULT([-E (BSD)])
835                SED_EXT=-E
836        elif test "x$gnu_sed_flag" = "xOK" ; then
837                AC_MSG_RESULT([-r (GNU)])
838                SED_EXT=-r
839        else
840                AC_MSG_RESULT([not available])
841                SED_EXT='N/A'
842        fi
843        AC_SUBST(SED_EXT)
844])
845
846dnl This macro tests for tar support of --no-same-owner
847AC_DEFUN([MP_TAR_NO_SAME_OWNER],[
848        AC_PATH_PROG(TAR, [tar])
849        AC_PATH_PROG(GNUTAR, [gnutar])
850       
851        AC_MSG_CHECKING([for which tar variant to use])
852        AS_IF([test -n "$GNUTAR"], [TAR_CMD=$GNUTAR], [TAR_CMD=$TAR])
853        AC_MSG_RESULT([$TAR_CMD])
854        AC_SUBST(TAR_CMD)
855
856        AC_MSG_CHECKING([for $TAR_CMD --no-same-owner support])
857        [no_same_owner_support=`$TAR_CMD --help 2>&1 | grep no-same-owner`]
858        if test -z "$no_same_owner_support" ; then
859                AC_MSG_RESULT([no])
860        else
861                AC_MSG_RESULT([yes])
862                TAR_CMD="$TAR_CMD --no-same-owner"
863        fi
864])
865
866dnl This macro tests for GNU patch
867AC_DEFUN([MP_PATCH_GNU_VERSION],[
868        AC_PATH_PROG(PATCH, [patch])
869        AC_PATH_PROG(GNUPATCH, [gpatch])
870       
871        AC_MSG_CHECKING([for GNU (FSF) patch])
872        AS_IF([test -n "$GNUPATCH"], [PATCH_CMD=$GNUPATCH], [PATCH_CMD=$PATCH])
873        [fsf_version=`$PATCH_CMD --version 2>&1 | grep "Free Software Foundation"`]
874        if test -z "$fsf_version" ; then
875                AC_MSG_RESULT([none])
876        else
877                AC_MSG_RESULT([$PATCH_CMD])
878                GNUPATCH="$PATCH_CMD"
879        fi
880])
881
882#------------------------------------------------------------------------
883# MP_CHECK_READLINK_IS_P1003_1A --
884#
885#       Check if readlink conforms to POSIX 1003.1a standard, define
886#       READLINK_IS_NOT_P1003_1A if it doesn't.
887#
888# Arguments:
889#       None.
890#
891# Requires:
892#       None.
893#
894# Depends:
895#               AC_LANG_PROGRAM
896#
897# Results:
898#       Result is cached.
899#
900#       If readlink doesn't conform to POSIX 1003.1a, defines the following variables:
901#               READLINK_IS_NOT_P1003_1A
902#
903#------------------------------------------------------------------------
904AC_DEFUN(MP_CHECK_READLINK_IS_P1003_1A, [
905        AC_MSG_CHECKING([if readlink conforms to POSIX 1003.1a])
906
907        AC_CACHE_VAL(mp_cv_readlink_is_posix_1003_1a, [
908                AC_COMPILE_IFELSE([
909                        AC_LANG_PROGRAM([
910                                        #include <unistd.h>
911                                        ssize_t readlink(const char *, char *, size_t);
912                                ], [
913                        ])
914                        ], [
915                                mp_cv_readlink_is_posix_1003_1a="yes"
916                        ], [
917                                mp_cv_readlink_is_posix_1003_1a="no"
918                        ]
919                )
920        ])
921
922        AC_MSG_RESULT(${mp_cv_readlink_is_posix_1003_1a})
923
924        if test x"${mp_cv_readlink_is_posix_1003_1a}" = "xno"; then
925                AC_DEFINE([READLINK_IS_NOT_P1003_1A], [], [Define to 1 if readlink does not conform with POSIX 1003.1a (where third argument is a size_t and return value is a ssize_t)])
926        fi
927
928        AC_SUBST(READLINK_IS_NOT_P1003_1A)
929])
930
931#------------------------------------------------------------------------
932# MP_WERROR --
933#
934#       Enable -Werror
935#
936# Arguments:
937#       None.
938#
939# Requires:
940#       none
941#
942# Depends:
943#       none
944#
945# Results:
946#       Substitutes WERROR_CFLAGS variable
947#------------------------------------------------------------------------
948AC_DEFUN([MP_WERROR],[
949        AC_REQUIRE([AC_PROG_CC])
950        AC_ARG_ENABLE(werror, AS_HELP_STRING([--enable-werror],[Add -Werror to CFLAGS. Used for development.]), [enable_werror=${enableval}], [enable_werror=no])
951        if test x"$enable_werror" != "xno"; then
952                CFLAGS_WERROR="-Werror"
953        else
954                CFLAGS_WERROR=""
955        fi
956        AC_SUBST([CFLAGS_WERROR])
957])
Note: See TracBrowser for help on using the repository browser.