source: trunk/base/aclocal.m4 @ 111491

Last change on this file since 111491 was 111491, checked in by cal@…, 7 years ago

autoconf: provide a variable that contains the archflags required to build universal on this system

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 30.6 KB
Line 
1dnl $Id: aclocal.m4 111491 2013-09-23 22:48:44Z cal@macports.org $
2builtin(include,m4/tcl.m4)
3builtin(include,m4/pthread.m4)
4builtin(include,m4/foundation.m4)
5
6#------------------------------------------------------------------------
7# MP_CHECK_FRAMEWORK_COREFOUNDATION --
8#
9#       Check if CoreFoundation framework is available, define HAVE_FRAMEWORK_COREFOUNDATION if so.
10#
11# Arguments:
12#       None.
13#
14# Requires:
15#       None.
16#
17# Depends:
18#               AC_LANG_PROGRAM
19#
20# Results:
21#       Result is cached.
22#
23#       If CoreFoundation framework is available, defines the following variables:
24#               HAVE_FRAMEWORK_COREFOUNDATION
25#
26#------------------------------------------------------------------------
27AC_DEFUN(MP_CHECK_FRAMEWORK_COREFOUNDATION, [
28        FRAMEWORK_LIBS="-framework CoreFoundation"
29
30        AC_MSG_CHECKING([for CoreFoundation framework])
31
32        AC_CACHE_VAL(mp_cv_have_framework_corefoundation, [
33                ac_save_LIBS="$LIBS"
34                LIBS="$FRAMEWORK_LIBS $LIBS"
35               
36                AC_LINK_IFELSE([
37                        AC_LANG_PROGRAM([
38                                        #include <CoreFoundation/CoreFoundation.h>
39                                ], [
40                                        CFURLRef url = CFURLCreateWithFileSystemPath(NULL, CFSTR("/testing"), kCFURLPOSIXPathStyle, 1);
41                                        CFArrayRef bundles = CFBundleCreateBundlesFromDirectory(NULL, url, CFSTR("pkg"));
42                        ])
43                        ], [
44                                mp_cv_have_framework_corefoundation="yes"
45                        ], [
46                                mp_cv_have_framework_corefoundation="no"
47                        ]
48                )
49
50                LIBS="$ac_save_LIBS"
51        ])
52
53        AC_MSG_RESULT(${mp_cv_have_framework_corefoundation})
54
55        if test x"${mp_cv_have_framework_corefoundation}" = "xyes"; then
56                AC_DEFINE([HAVE_FRAMEWORK_COREFOUNDATION], [], [Define if CoreFoundation framework is available])
57        fi
58
59        AC_SUBST(HAVE_FRAMEWORK_COREFOUNDATION)
60])
61
62
63#------------------------------------------------------------------------
64# MP_CHECK_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER --
65#
66#       Check if if the routine CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER
67#       is available in CoreFoundation.
68#
69# Arguments:
70#       None.
71#
72# Requires:
73#       None.
74#
75# Depends:
76#               AC_LANG_PROGRAM
77#
78# Results:
79#       Result is cached.
80#
81#       If function CFNotificationCenterGetDarwinNotifyCenter is in the CoreFoundation framework, defines the following variables:
82#               HAVE_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER
83#
84#------------------------------------------------------------------------
85AC_DEFUN(MP_CHECK_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER, [
86        FRAMEWORK_LIBS="-framework CoreFoundation"
87
88        AC_MSG_CHECKING([for CFNotificationCenterGetDarwinNotifyCenter])
89
90        AC_CACHE_VAL(mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter, [
91                ac_save_LIBS="$LIBS"
92                LIBS="$FRAMEWORK_LIBS $LIBS"
93               
94                AC_LINK_IFELSE([
95                        AC_LANG_PROGRAM([
96                                        #include <CoreFoundation/CoreFoundation.h>
97                                ], [
98                                        CFNotificationCenterRef ref = CFNotificationCenterGetDarwinNotifyCenter();
99                        ])
100                        ], [
101                                mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter="yes"
102                        ], [
103                                mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter="no"
104                        ]
105                )
106
107                LIBS="$ac_save_LIBS"
108        ])
109
110        AC_MSG_RESULT(${mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter})
111
112        if test x"${mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter}" = "xyes"; then
113                AC_DEFINE([HAVE_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER], [], [Define if function CFNotificationCenterGetDarwinNotifyCenter in CoreFoundation framework])
114        fi
115
116        AC_SUBST(HAVE_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER)
117])
118
119
120#------------------------------------------------------------------------
121# MP_CHECK_FRAMEWORK_SYSTEMCONFIGURATION --
122#
123#       Check if SystemConfiguration framework is available, define HAVE_FRAMEWORK_SYSTEMCONFIGURATION if so.
124#
125# Arguments:
126#       None.
127#
128# Requires:
129#       None.
130#
131# Depends:
132#               AC_LANG_PROGRAM
133#
134# Results:
135#       Result is cached.
136#
137#       If SystemConfiguration framework is available, defines the following variables:
138#               HAVE_FRAMEWORK_SYSTEMCONFIGURATION
139#
140#------------------------------------------------------------------------
141AC_DEFUN(MP_CHECK_FRAMEWORK_SYSTEMCONFIGURATION, [
142        FRAMEWORK_LIBS="-framework SystemConfiguration"
143
144        AC_MSG_CHECKING([for SystemConfiguration framework])
145
146        AC_CACHE_VAL(mp_cv_have_framework_systemconfiguration, [
147                ac_save_LIBS="$LIBS"
148                LIBS="$FRAMEWORK_LIBS $LIBS"
149               
150                AC_LINK_IFELSE([
151                        AC_LANG_PROGRAM([
152                                        #include <SystemConfiguration/SystemConfiguration.h>
153                                ], [
154                                        int err = SCError();
155                                        SCDynamicStoreRef dsRef = SCDynamicStoreCreate(NULL, NULL, NULL, NULL);
156                        ])
157                        ], [
158                                mp_cv_have_framework_systemconfiguration="yes"
159                        ], [
160                                mp_cv_have_framework_systemconfiguration="no"
161                        ]
162                )
163
164                LIBS="$ac_save_LIBS"
165        ])
166
167        AC_MSG_RESULT(${mp_cv_have_framework_systemconfiguration})
168
169        if test x"${mp_cv_have_framework_systemconfiguration}" = "xyes"; then
170                AC_DEFINE([HAVE_FRAMEWORK_SYSTEMCONFIGURATION], [], [Define if SystemConfiguration framework is available])
171        fi
172
173        AC_SUBST(HAVE_FRAMEWORK_SYSTEMCONFIGURATION)
174])
175
176
177#------------------------------------------------------------------------
178# MP_CHECK_FRAMEWORK_IOKIT --
179#
180#       Check if IOKit framework is available, define HAVE_FRAMEWORK_IOKIT if so.
181#
182# Arguments:
183#       None.
184#
185# Requires:
186#       None.
187#
188# Depends:
189#               AC_LANG_PROGRAM
190#
191# Results:
192#       Result is cached.
193#
194#       If IOKit framework is available, defines the following variables:
195#               HAVE_FRAMEWORK_IOKIT
196#
197#------------------------------------------------------------------------
198AC_DEFUN(MP_CHECK_FRAMEWORK_IOKIT, [
199        FRAMEWORK_LIBS="-framework IOKit"
200
201        AC_MSG_CHECKING([for IOKit framework])
202
203        AC_CACHE_VAL(mp_cv_have_framework_iokit, [
204                ac_save_LIBS="$LIBS"
205                LIBS="$FRAMEWORK_LIBS $LIBS"
206               
207                AC_LINK_IFELSE([
208                        AC_LANG_PROGRAM([
209                                        #include <IOKit/IOKitLib.h>
210                                ], [
211                                        IOCreateReceivePort(0, NULL);
212                                        IORegisterForSystemPower(0, NULL, NULL, NULL);
213                        ])
214                        ], [
215                                mp_cv_have_framework_iokit="yes"
216                        ], [
217                                mp_cv_have_framework_iokit="no"
218                        ]
219                )
220
221                LIBS="$ac_save_LIBS"
222        ])
223
224        AC_MSG_RESULT(${mp_cv_have_framework_iokit})
225
226        if test x"${mp_cv_have_framework_iokit}" = "xyes"; then
227                AC_DEFINE([HAVE_FRAMEWORK_IOKIT], [], [Define if IOKit framework is available])
228        fi
229
230        AC_SUBST(HAVE_FRAMEWORK_IOKIT)
231])
232
233
234dnl This macro checks if the user specified a ports tree
235dnl explicitly. If not, search for it
236
237# MP_PATH_PORTSDIR(DEFAULT_PORTSDIR)
238#---------------------------------------
239 AC_DEFUN([MP_PATH_PORTSDIR],[
240        dnl For ease of reading, run after gcc has been found/configured
241        AC_REQUIRE([AC_PROG_CC])
242
243        AC_ARG_WITH(ports-dir, [AS_HELP_STRING([--with-ports-dir=DIR],[Specify alternate ports directory])], [ portsdir="$withval" ] )
244
245
246        AC_MSG_CHECKING([for ports tree])
247        if test "x$portsdir" != "x" ; then
248          if test -d "$portsdir" -a -e "$portsdir/PortIndex" ; then
249                :
250          else
251                AC_MSG_ERROR([$portsdir not a valid ports tree])
252          fi
253        else
254                dnl If the user didn't give a path, look for default
255                if test "x$1" != "x" ; then
256                  if test -d "$1" -a -e "$1/PortIndex" ; then
257                        portsdir=$1
258                  fi
259                fi
260        fi
261
262        if test "x$portsdir" != "x" ; then
263                AC_MSG_RESULT($portsdir)
264                PORTSDIR="$portsdir"
265                AC_SUBST(PORTSDIR)
266        else
267                AC_MSG_WARN([No ports tree found])
268        fi
269
270         ])
271
272
273# MP_PATH_MPCONFIGDIR
274#---------------------------------------
275AC_DEFUN([MP_PATH_MPCONFIGDIR],[
276        dnl if the user actually specified --prefix, shift
277        dnl mpconfigdir to $prefix/etc/macports
278        dnl     AC_REQUIRE([MP_PATH_PORTSDIR])
279       
280        AC_MSG_CHECKING([for MacPorts config directory])
281
282        mpconfigdir='${sysconfdir}/macports'
283
284        AC_MSG_RESULT([$mpconfigdir])
285        MPCONFIGDIR="$mpconfigdir"
286        AC_SUBST(MPCONFIGDIR)
287
288        ])
289
290# MP_CHECK_OLDLAYOUT
291#---------------------------------------
292AC_DEFUN([MP_CHECK_OLDLAYOUT],[
293        dnl Bail if there is an existing install of DP/MP older than 1.5
294
295        AC_MSG_CHECKING([that any existing MacPorts install can be upgraded])
296
297        eval dpversionfile="${sysconfdir}/ports/dp_version"
298        if test -f "$dpversionfile"; then
299                AC_MSG_ERROR([Existing MacPorts or DarwinPorts install is too old to be upgraded. Install MacPorts 1.7.1 first.])
300        else
301                AC_MSG_RESULT([yes])
302        fi
303
304        ])
305
306# MP_CHECK_NOROOTPRIVILEGES
307#-------------------------------------------------
308AC_DEFUN([MP_CHECK_NOROOTPRIVILEGES],[
309        dnl if with user specifies --with-no-root-privileges,
310        dnl use current user and group.
311        dnl use ~/Library/Tcl as Tcl package directory
312                AC_REQUIRE([MP_PATH_MPCONFIGDIR])
313
314        AC_ARG_WITH(no-root-privileges, [AS_HELP_STRING([--with-no-root-privileges],[Specify that MacPorts should be installed in your home directory])], [ROOTPRIVS=$withval] )
315
316        if test "${ROOTPRIVS+set}" = set; then
317
318                # Set install-user to current user
319                AC_MSG_CHECKING([for install user])
320                DSTUSR=`id -un`
321                AC_MSG_RESULT([$DSTUSR])
322                AC_SUBST(DSTUSR)
323               
324                # Set install-group to current user
325                AC_MSG_CHECKING([for install group])
326                DSTGRP=`id -gn`
327                AC_MSG_RESULT([$DSTGRP])
328                AC_SUBST(DSTGRP)
329
330                # Set run-user to current user
331                AC_MSG_CHECKING([for macports user])
332                RUNUSR=`id -un`
333                AC_MSG_RESULT([$RUNUSR])
334                AC_SUBST(RUNUSR)
335
336                # Set Tcl package directory to ~/Library/Tcl
337            AC_MSG_CHECKING(for Tcl package directory)
338                ac_cv_c_tclpkgd=`eval echo ~$DSTUSR/Library/Tcl`
339            # Convert to a native path and substitute into the output files.
340            PACKAGE_DIR_NATIVE=`${CYGPATH} ${ac_cv_c_tclpkgd}`
341            TCL_PACKAGE_DIR=${PACKAGE_DIR_NATIVE}
342            AC_SUBST(TCL_PACKAGE_DIR)
343                if test x"${ac_cv_c_tclpkgd}" = x ; then
344                        AC_MSG_ERROR(Tcl package directory not found.  Please specify its location with --with-tclpackage)
345            else
346                        AC_MSG_RESULT(${ac_cv_c_tclpkgd})
347            fi
348        fi
349
350])
351
352# MP_CHECK_RUNUSER
353#-------------------------------------------------
354AC_DEFUN([MP_CHECK_RUNUSER],[
355        dnl if with user specifies --with-macports-user,
356        dnl use it. otherwise default to platform defaults
357       AC_REQUIRE([MP_PATH_MPCONFIGDIR])
358
359        AC_ARG_WITH(macports-user, [AS_HELP_STRING([--with-macports-user=USER],[Specify user to drop privileges to, if possible, during compiles etc.])], [ RUNUSR=$withval ] )
360       
361        AC_MSG_CHECKING([for macports user])
362        if test "x$RUNUSR" = "x" ; then
363           RUNUSR=macports
364        fi
365
366        AC_MSG_RESULT([$RUNUSR])
367        AC_SUBST(RUNUSR)
368])
369
370
371# MP_SHARED_DIRECTORY
372#-------------------------------------------------
373AC_DEFUN([MP_SHARED_DIRECTORY],[
374        dnl if with user specifies --with-shared-directory,
375        dnl use 0775 permissions for ${prefix} directories
376        AC_REQUIRE([MP_PATH_MPCONFIGDIR])
377
378        AC_ARG_WITH(shared-directory, [AS_HELP_STRING([--with-shared-directory],[Use 0775 permissions for installed directories])], [ SHAREDIR=$withval ] )
379
380        if test "${SHAREDIR+set}" = set; then   
381                AC_MSG_CHECKING([whether to share the install directory with all members of the install group])
382            DSTMODE=0775
383
384                AC_MSG_RESULT([$DSTMODE])
385                AC_SUBST(DSTMODE)
386        fi
387])
388
389# MP_CHECK_INSTALLUSER
390#-------------------------------------------------
391AC_DEFUN([MP_CHECK_INSTALLUSER],[
392        dnl if with user specifies --with-install-user,
393        dnl use it. otherwise default to platform defaults
394        AC_REQUIRE([MP_PATH_MPCONFIGDIR])
395
396        AC_ARG_WITH(install-user, [AS_HELP_STRING([--with-install-user=USER],[Specify user ownership of installed files])], [ DSTUSR=$withval ] )
397       
398        AC_MSG_CHECKING([for install user])
399        if test "x$DSTUSR" = "x" ; then
400           DSTUSR=root
401        fi
402
403        AC_MSG_RESULT([$DSTUSR])
404        AC_SUBST(DSTUSR)
405])
406
407# MP_CHECK_INSTALLGROUP
408#-------------------------------------------------
409AC_DEFUN([MP_CHECK_INSTALLGROUP],[
410        dnl if with user specifies --with-install-group,
411        dnl use it. otherwise default to platform defaults
412        AC_REQUIRE([MP_CHECK_INSTALLUSER])
413
414        AC_ARG_WITH(install-group, [AS_HELP_STRING([--with-install-group=GROUP],[Specify group ownership of installed files])], [ DSTGRP=$withval ] )
415
416        AC_MSG_CHECKING([for install group])
417        if test "x$DSTGRP" = "x" ; then
418           
419           case $host_os in
420           darwin*)
421                DSTGRP="admin"
422                ;;
423           freebsd*)
424                DSTGRP="wheel"
425                ;;
426           linux*)
427                DSTGRP="root"
428                ;;
429           *)
430                DSTGRP="wheel"
431                ;;
432           esac
433        fi
434
435        AC_MSG_RESULT([$DSTGRP])
436        AC_SUBST(DSTGRP)
437])
438
439# MP_DIRECTORY_MODE
440#-------------------------------------------------
441AC_DEFUN([MP_DIRECTORY_MODE],[
442        dnl if with user specifies --with-directory-mode,
443        dnl use the specified permissions for ${prefix} directories
444        dnl otherwise use 0755
445        AC_REQUIRE([MP_PATH_MPCONFIGDIR])
446
447        AC_ARG_WITH(directory-mode, [AS_HELP_STRING([--with-directory-mode=MODE],[Specify directory mode of installed directories])], [ DSTMODE=$withval ] )
448       
449        AC_MSG_CHECKING([what permissions to use for installation directories])
450        if test "x$DSTMODE" = "x" ; then
451           DSTMODE=0755
452        fi
453
454        AC_MSG_RESULT([$DSTMODE])
455        AC_SUBST(DSTMODE)
456])
457
458# MP_PATH_APPLICATIONS
459#---------------------------------------
460AC_DEFUN([MP_PATH_APPLICATIONS],[
461        AC_REQUIRE([MP_CHECK_INSTALLUSER])
462
463    AC_ARG_WITH(applications-dir,[AS_HELP_STRING([--with-applications-dir],[Applications installation directory.])], MPAPPLICATIONSDIR=${withval})
464
465    oldprefix=$prefix
466    if test "x$prefix" = "xNONE" ; then
467        prefix=$ac_default_prefix
468    fi
469    AC_MSG_CHECKING([for Applications installation directory])
470
471        if test "x$MPAPPLICATIONSDIR" = "x" ; then
472            if test "$DSTUSR" = "root" ; then
473                MPAPPLICATIONSDIR="/Applications/MacPorts"
474            else
475                MPAPPLICATIONSDIR="$(eval echo ~$DSTUSR)/Applications/MacPorts"
476            fi
477        fi
478
479        AC_MSG_RESULT([$MPAPPLICATIONSDIR])
480    AC_SUBST(MPAPPLICATIONSDIR)
481    prefix=$oldprefix
482])
483
484# MP_PATH_FRAMEWORKS
485#---------------------------------------
486AC_DEFUN([MP_PATH_FRAMEWORKS],[
487        AC_REQUIRE([MP_CHECK_INSTALLUSER])
488
489    AC_ARG_WITH(frameworks-dir,[AS_HELP_STRING([--with-frameworks-dir],[Frameworks installation directory.])], MPFRAMEWORKSDIR=${withval})
490
491    oldprefix=$prefix
492    if test "x$prefix" = "xNONE" ; then
493        prefix=$ac_default_prefix
494    fi
495    AC_MSG_CHECKING([for Frameworks installation directory])
496
497        if test "x$MPFRAMEWORKSDIR" = "x" ; then
498                MPFRAMEWORKSDIR="${prefix}/Library/Frameworks"
499        fi
500
501        AC_MSG_RESULT([$MPFRAMEWORKSDIR])
502    AC_SUBST(MPFRAMEWORKSDIR)
503    prefix=$oldprefix
504])
505
506
507# MP_UNIVERSAL_OPTIONS
508#---------------------------------------
509AC_DEFUN([MP_UNIVERSAL_OPTIONS],[
510  AC_ARG_WITH(universal-archs,[AS_HELP_STRING([--with-universal-archs="CPU"],[Universal CPU architectures (space separated)])], UNIVERSAL_ARCHS=${withval})
511
512  if test "x$UNIVERSAL_ARCHS" = "x"; then
513    case "$MACOSX_VERSION" in
514      10.[[0-5]]*)
515        UNIVERSAL_ARCHS="i386 ppc"
516        ;;
517      *)
518        UNIVERSAL_ARCHS="x86_64 i386"
519        ;;
520    esac
521  fi
522
523  UNIVERSAL_ARCHFLAGS=
524  for arch in $UNIVERSAL_ARCHS; do
525    UNIVERSAL_ARCHFLAGS="$UNIVERSAL_ARCHFLAGS -arch $arch"
526  done
527
528  AC_MSG_CHECKING([for Universal CPU architectures])
529  AC_MSG_RESULT([$UNIVERSAL_ARCHS])
530  AC_SUBST(UNIVERSAL_ARCHS)
531  AC_SUBST(UNIVERSAL_ARCHFLAGS)
532])
533
534# MP_LIB_MD5
535#---------------------------------------
536# Check for an md5 implementation
537AC_DEFUN([MP_LIB_MD5],[
538
539        # Check for libmd from FreeBSD, which is preferred
540        AC_CHECK_LIB([md], [MD5File],[
541                AC_CHECK_HEADERS([md5.h sha.h], ,[
542                        AC_MSG_ERROR([libmd was found, but md5.h or sha.h is missing.])
543                ])
544                ac_save_LIBS="$LIBS"
545                LIBS="-lmd $LIBS"
546                AC_CHECK_FUNCS([SHA1_File])
547                LIBS="$ac_save_LIBS"
548                AC_CHECK_HEADERS([ripemd.h sha256.h])
549                AC_DEFINE([HAVE_LIBMD], ,[Define if you have the `md' library (-lmd).])
550                MD5_LIBS="-lmd"]
551        )
552        if test "x$MD5_LIBS" = "x"; then
553                # If libmd is not found, check for libcrypto from OpenSSL
554                AC_CHECK_LIB([crypto], [MD5_Update],[
555                        AC_CHECK_HEADERS([openssl/md5.h openssl/sha.h], ,[
556                                AC_MSG_ERROR([libcrypto was found, but openssl/md5.h or openssl/sha.h is missing.])
557                        ])
558                        AC_CHECK_HEADERS([openssl/ripemd.h])
559                        ac_save_LIBS="$LIBS"
560                        LIBS="-lcrypto $LIBS"
561                        AC_CHECK_FUNCS([SHA256_Update])
562                        LIBS="$ac_save_LIBS"
563                        AC_DEFINE([HAVE_LIBCRYPTO], ,[Define if you have the `crypto' library (-lcrypto).])
564                        MD5_LIBS="-lcrypto"]
565                )
566        fi
567        if test "x$MD5_LIBS" = "x"; then
568                AC_MSG_ERROR([Neither CommonCrypto, libmd nor libcrypto were found. A working md5 implementation is required.])
569        fi
570        AC_SUBST([MD5_LIBS])
571])
572
573# MP_PROG_DAEMONDO
574#---------------------------------------
575AC_DEFUN([MP_PROG_DAEMONDO],[
576        AC_REQUIRE([MP_CHECK_FRAMEWORK_COREFOUNDATION])
577        AC_REQUIRE([MP_CHECK_FRAMEWORK_SYSTEMCONFIGURATION])
578        AC_REQUIRE([MP_CHECK_FRAMEWORK_IOKIT])
579        AC_REQUIRE([MP_CHECK_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER])
580       
581    AC_MSG_CHECKING(for whether we will build daemondo)
582    result=no
583        case $host_os in
584        darwin*)
585                if test "x$mp_cv_have_framework_corefoundation" == "xyes" &&
586                   test "x$mp_cv_have_framework_systemconfiguration" == "xyes" &&
587                   test "x$mp_cv_have_framework_iokit" == "xyes" &&
588                   test "x$mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter" == "xyes"; then
589                        result=yes
590                        EXTRA_PROGS="$EXTRA_PROGS daemondo"
591                        AC_CONFIG_FILES([src/programs/daemondo/Makefile])
592                fi
593                ;;
594        *)
595        esac
596        AC_MSG_RESULT(${result})
597])
598
599#------------------------------------------------------------------------
600# MP_TCL_PACKAGE_DIR --
601#
602#       Locate the correct directory for Tcl package installation
603#
604# Arguments:
605#       None.
606#
607# Requires:
608#       TCLVERSION must be set
609#       CYGPATH must be set
610#       TCLSH must be set
611#
612# Results:
613#
614#       Adds a --with-tclpackage switch to configure.
615#       Result is cached.
616#
617#       Substs the following vars:
618#               TCL_PACKAGE_DIR
619#------------------------------------------------------------------------
620
621AC_DEFUN(MP_TCL_PACKAGE_DIR, [
622        AC_REQUIRE([MP_CHECK_INSTALLUSER])
623
624    AC_MSG_CHECKING(for Tcl package directory)
625
626    AC_ARG_WITH(tclpackage, [  --with-tclpackage       Tcl package installation directory.], with_tclpackagedir=${withval})
627
628    if test x"${with_tclpackagedir}" != x ; then
629        ac_cv_c_tclpkgd=${with_tclpackagedir}
630    else
631        AC_CACHE_VAL(ac_cv_c_tclpkgd, [
632            # Use the value from --with-tclpackage, if it was given
633
634            if test x"${with_tclpackagedir}" != x ; then
635                echo "tclpackagedir"
636                ac_cv_c_tclpkgd=${with_tclpackagedir}
637            else
638                # On darwin we can do some intelligent guessing
639                case $host_os in
640                    darwin*)
641                        tcl_autopath=`echo 'puts -nonewline \$auto_path' | $TCLSH`
642                        for path in $tcl_autopath; do
643                        if test "$DSTUSR" = "root" ; then
644                            if test "$path" = "/Library/Tcl"; then
645                                ac_cv_c_tclpkgd="$path"
646                                break
647                            fi
648                            if test "$path" = "/System/Library/Tcl"; then
649                                if test -d "$path"; then
650                                    ac_cv_c_tclpkgd="$path"
651                                    break
652                                fi
653                            fi
654                        elif test "$path" = "~/Library/Tcl"; then
655                            ac_cv_c_tclpkgd=`eval echo ~$DSTUSR/Library/Tcl`
656                            break
657                        fi
658                        done
659                    ;;
660                esac
661                if test x"${ac_cv_c_tclpkgd}" = x ; then
662                    # Fudge a path from the first entry in the auto_path
663                    tcl_pkgpath=`echo 'puts -nonewline [[lindex \$auto_path 0]]' | $TCLSH`
664                    if test -d "$tcl_pkgpath"; then
665                        ac_cv_c_tclpkgd="$tcl_pkgpath"
666                    fi
667                    # If the first entry does not exist, do nothing
668                fi
669            fi
670        ])
671    fi
672
673    if test x"${ac_cv_c_tclpkgd}" = x ; then
674        AC_MSG_ERROR(Tcl package directory not found.  Please specify its location with --with-tclpackage)
675    else
676        AC_MSG_RESULT(${ac_cv_c_tclpkgd})
677    fi
678
679    # Convert to a native path and substitute into the output files.
680
681    PACKAGE_DIR_NATIVE=`${CYGPATH} ${ac_cv_c_tclpkgd}`
682
683    TCL_PACKAGE_DIR=${PACKAGE_DIR_NATIVE}
684
685    AC_SUBST(TCL_PACKAGE_DIR)
686])
687
688# MP_PROG_TCLSH
689#---------------------------------------
690AC_DEFUN([MP_PROG_TCLSH],[
691
692
693        case $host_os in
694                freebsd*)
695                        # FreeBSD installs a dummy tclsh (annoying)
696                        # Look for a real versioned tclsh with threads first
697                        # Look for a real versioned tclsh without threads second
698                        AC_PATH_PROG([TCLSH], [tclsh${TCL_VERSION}-threads tclsh${TCL_VERSION} tclsh])
699                        ;;
700                *)
701                        # Otherwise, look for a non-versioned tclsh
702                        AC_PATH_PROG([TCLSH], [tclsh tclsh${TCL_VERSION}])
703                        ;;
704        esac
705        if test "x$TCLSH" = "x" ; then
706                AC_MSG_ERROR([Could not find tclsh])
707        fi
708
709        AC_SUBST(TCLSH)
710])
711
712# MP_TCL_PACKAGE
713#       Determine if a Tcl package is present.
714#
715# Arguments:
716#       Package name (may include the version)
717#
718# Syntax:
719#   MP_TCL_PACKAGE (package, [action-if-found], [action-if-not-found])
720#
721# Requires:
722#       TCLSH must be set
723#
724# Results:
725#       Execute action-if-found or action-if-not-found
726#---------------------------------------
727AC_DEFUN([MP_TCL_PACKAGE],[
728        AC_MSG_CHECKING([for Tcl $1 package])
729        package_present=`echo 'if {[[catch {package require $1}]]} {puts -nonewline 0} else {puts -nonewline 1}' | $TCLSH`
730        AS_IF([test "$package_present" = "1"], [$2], [$3])[]
731])
732
733# MP_TCL_THREAD_SUPPORT
734#       Determine if thread support is available in tclsh.
735#
736# Arguments:
737#       None.
738#
739# Requires:
740#       TCLSH must be set
741#
742# Results:
743#   Fails if thread support isn't available.
744#---------------------------------------
745AC_DEFUN([MP_TCL_THREAD_SUPPORT],[
746        AC_MSG_CHECKING([whether tclsh was compiled with threads])
747        tcl_threadenabled=`echo 'puts -nonewline [[info exists tcl_platform(threaded)]]' | $TCLSH`
748        if test "$tcl_threadenabled" = "1" ; then
749                AC_MSG_RESULT([yes])
750        else
751                AC_MSG_RESULT([no])
752                AC_MSG_ERROR([tcl wasn't compiled with threads enabled])
753        fi
754])
755
756# MP_LIBCURL_FLAGS
757#       Sets the flags to compile with libcurl.
758#
759# Arguments:
760#       None.
761#
762# Requires:
763#   curl-config or user parameters to define the flags.
764#
765# Results:
766#   defines some help strings.
767#   sets CFLAGS_LIBCURL and LDFLAGS_LIBCURL
768#---------------------------------------
769AC_DEFUN([MP_LIBCURL_FLAGS],[
770        AC_ARG_WITH(curlprefix,
771                   [  --with-curlprefix       base directory for the cURL install '/usr', '/usr/local',...],
772                   [  curlprefix=$withval ])
773
774        if test "x$curlprefix" = "x"; then
775                AC_PATH_PROG([CURL_CONFIG], [curl-config])
776        else
777                AC_PATH_PROG([CURL_CONFIG], [curl-config], , [$curlprefix/bin])
778        fi
779
780        if test "x$CURL_CONFIG" = "x"; then
781                AC_MSG_ERROR([cannot find curl-config. Is libcurl installed?])
782        fi
783
784        CFLAGS_LIBCURL=$($CURL_CONFIG --cflags)
785        if test "x$curlprefix" = "x"; then
786                # System curl-config emits absurd output for --libs
787                # See rdar://7244457
788                LDFLAGS_LIBCURL="-lcurl"
789        else
790                # Due to a bug in dist, --arch flags are improperly supplied by curl-config.
791                # Get rid of them.
792                LDFLAGS_LIBCURL=$($CURL_CONFIG --libs | [sed 's/-arch [A-Za-z0-9_]* //g'])
793        fi
794
795        AC_SUBST(CFLAGS_LIBCURL)
796        AC_SUBST(LDFLAGS_LIBCURL)
797])
798
799# MP_SQLITE3_FLAGS
800#       Sets the flags to compile with libsqlite3 and tclsqlite3.
801#
802# Arguments:
803#       None.
804#
805# Requires:
806#   pkgconfig, libsqlite3 in /usr/lib, or user parameters to define the flags.
807#
808# Results:
809#   defines some help strings.
810#   sets CFLAGS_SQLITE3 and LDFLAGS_SQLITE3
811#---------------------------------------
812AC_DEFUN([MP_SQLITE3_FLAGS],[
813    # first sqlite3 itself
814        AC_ARG_WITH(sqlite3prefix,
815                   [  --with-sqlite3prefix       base directory for the sqlite3 install '/usr', '/usr/local',...],
816                   [  sqlite3prefix=$withval ])
817
818        if test "x$sqlite3prefix" = "x"; then
819                # see if it's somewhere like /usr that needs no extra flags
820                LDFLAGS_SQLITE3="-lsqlite3"
821                AC_CHECK_HEADER(sqlite3.h, [],[
822                    # nope - try pkg-config
823                        AC_PATH_PROG([PKG_CONFIG], [pkg-config])
824                        if test "x$PKG_CONFIG" = "x" || ! $PKG_CONFIG --exists sqlite3; then
825                                AC_MSG_ERROR([cannot find sqlite3 header])
826                        else
827                                CFLAGS_SQLITE3=$($PKG_CONFIG --cflags sqlite3)
828                                LDFLAGS_SQLITE3=$($PKG_CONFIG --libs sqlite3)
829                                # for tclsqlite below
830                                mp_sqlite3_dir=$($PKG_CONFIG --variable=prefix sqlite3)
831                                if test "x$mp_sqlite3_dir" != "x"; then
832                                        mp_sqlite3_dir=${mp_sqlite3_dir}/lib/sqlite3
833                                fi
834                        fi
835                ])
836        else
837            CFLAGS_SQLITE3="-I${sqlite3prefix}/include"
838                LDFLAGS_SQLITE3="-L${sqlite3prefix}/lib -lsqlite3"
839        fi
840
841    # check if we have sqlite3ext.h, using the appropriate cppflags
842    CPPFLAGS_OLD="${CPPFLAGS}"
843    CPPFLAGS="${CPPFLAGS} ${CFLAGS_SQLITE3}"
844    AC_CHECK_HEADERS(sqlite3ext.h)
845    CPPFLAGS="${CPPFLAGS_OLD}"
846
847        AC_SUBST(CFLAGS_SQLITE3)
848        AC_SUBST(LDFLAGS_SQLITE3)
849
850        # now the sqlite Tcl bindings
851        AC_ARG_WITH(tcl-sqlite3,
852                AS_HELP_STRING([--with-tcl-sqlite3=DIR],
853                        [directory for Tcl sqlite3 (default /usr/lib/sqlite3)]),
854                [mp_sqlite3_dir=$withval])
855
856    if test "x$mp_sqlite3_dir" = "x"; then
857        case $host_os in
858            darwin*)
859                mp_sqlite3_dir="/usr/lib/sqlite3"
860                ;;
861            freebsd*)
862                mp_sqlite3_dir="/usr/local/lib/sqlite"
863                ;;
864            *)
865                mp_sqlite3_dir="/usr/share/tcl${TCL_VERSION}/sqlite3"
866                ;;
867        esac
868    fi
869
870        AC_CACHE_CHECK([for Tcl sqlite3 location], [mp_cv_sqlite3_dir],
871                [mp_cv_sqlite3_dir=
872                test -r "${mp_sqlite3_dir}/pkgIndex.tcl" && mp_cv_sqlite3_dir=$mp_sqlite3_dir
873                ])
874
875        SQLITE3_TCL_DIR=$mp_cv_sqlite3_dir
876        AC_SUBST(SQLITE3_TCL_DIR)
877])
878
879dnl This macro tests if the compiler supports GCC's
880dnl __attribute__ syntax for unused variables/parameters
881AC_DEFUN([MP_COMPILER_ATTRIBUTE_UNUSED], [
882        AC_MSG_CHECKING([how to mark unused variables])
883        AC_COMPILE_IFELSE(
884                [AC_LANG_SOURCE([[int a __attribute__ ((unused));]])],
885                [AC_DEFINE(UNUSED, [__attribute__((unused))], [Attribute to mark unused variables])],
886                [AC_DEFINE(UNUSED, [])])
887
888        AC_MSG_RESULT([])
889       
890])
891
892dnl This macro ensures MP installation prefix bin/sbin paths are NOT in PATH
893dnl for configure to prevent potential problems when base/ code is updated
894dnl and ports are installed that would match needed items.
895AC_DEFUN([MP_PATH_SCAN],[
896        oldprefix=$prefix
897        if test "x$prefix" = "xNONE" ; then
898                prefix=$ac_default_prefix
899        fi
900        oldPATH=$PATH
901        newPATH=
902        as_save_IFS=$IFS; IFS=$PATH_SEPARATOR
903        for as_dir in $oldPATH
904        do
905                IFS=$as_save_IFS
906                if test "x$as_dir" != "x$prefix/bin" &&
907                        test "x$as_dir" != "x$prefix/sbin"; then
908                        if test -z "$newPATH"; then
909                                newPATH=$as_dir
910                        else
911                                newPATH=$newPATH$PATH_SEPARATOR$as_dir
912                        fi
913                fi
914        done
915        PATH=$newPATH; export PATH
916        AC_SUBST(PATH_CLEANED,$newPATH)
917        prefix=$oldprefix
918])
919
920dnl This macro tests for sed support of -E (BSD) or -r (GNU)
921AC_DEFUN([MP_SED_EXTENDED_REGEXP],[
922        AC_PATH_PROG(SED, [sed])
923
924        if test "x$SED" = "x"; then
925                AC_MSG_ERROR([cannot find sed. Is sed installed?])
926        fi
927
928        AC_MSG_CHECKING([which sed flag to use for extended regexp])
929        [any_sed_flag=`echo foo | $SED    -e s/foo+/OK/ 2>&1 | grep OK`]
930        [bsd_sed_flag=`echo foo | $SED -E -e s/foo+/OK/ 2>&1 | grep OK`]
931        [gnu_sed_flag=`echo foo | $SED -r -e s/foo+/OK/ 2>&1 | grep OK`]
932        if test "x$any_sed_flag" = "xOK" ; then
933                AC_MSG_RESULT([none])
934                SED_EXT=
935        elif test "x$bsd_sed_flag" = "xOK" ; then
936                AC_MSG_RESULT([-E (BSD)])
937                SED_EXT=-E
938        elif test "x$gnu_sed_flag" = "xOK" ; then
939                AC_MSG_RESULT([-r (GNU)])
940                SED_EXT=-r
941        else
942                AC_MSG_RESULT([not available])
943                SED_EXT='N/A'
944        fi
945        AC_SUBST(SED_EXT)
946])
947
948dnl This macro tests for tar support of -q (BSD) or not (GNU)
949AC_DEFUN([MP_TAR_FAST_READ],[
950        AC_PATH_PROG(TAR, [tar])
951       
952        AC_MSG_CHECKING([whether tar supports -q])
953        if $TAR -t -q -f - </dev/null 2>/dev/null ; then
954                AC_MSG_RESULT([yes (bsdtar)])
955                TAR_Q='q'
956        else
957                AC_MSG_RESULT([no (gnutar)])
958                TAR_Q=
959        fi
960        AC_SUBST(TAR_Q)
961])
962
963dnl This macro tests for tar support of --no-same-owner
964AC_DEFUN([MP_TAR_NO_SAME_OWNER],[
965        AC_PATH_PROG(TAR, [tar])
966        AC_PATH_PROG(GNUTAR, [gnutar])
967       
968        AC_MSG_CHECKING([for which tar variant to use])
969        AS_IF([test -n "$GNUTAR"], [TAR_CMD=$GNUTAR], [TAR_CMD=$TAR])
970        AC_MSG_RESULT([$TAR_CMD])
971        AC_SUBST(TAR_CMD)
972
973        AC_MSG_CHECKING([for $TAR_CMD --no-same-owner support])
974        [no_same_owner_support=`$TAR_CMD --help 2>&1 | grep no-same-owner`]
975        if test -z "$no_same_owner_support" ; then
976                AC_MSG_RESULT([no])
977        else
978                AC_MSG_RESULT([yes])
979                TAR_CMD="$TAR_CMD --no-same-owner"
980        fi
981])
982
983dnl This macro tests for GNU patch
984AC_DEFUN([MP_PATCH_GNU_VERSION],[
985        AC_PATH_PROG(PATCH, [patch])
986        AC_PATH_PROG(GNUPATCH, [gpatch])
987       
988        AC_MSG_CHECKING([for GNU (FSF) patch])
989        AS_IF([test -n "$GNUPATCH"], [PATCH_CMD=$GNUPATCH], [PATCH_CMD=$PATCH])
990        [fsf_version=`$PATCH_CMD --version 2>&1 | grep "Free Software Foundation"`]
991        if test -z "$fsf_version" ; then
992                AC_MSG_RESULT([none])
993        else
994                AC_MSG_RESULT([$PATCH_CMD])
995                GNUPATCH="$PATCH_CMD"
996        fi
997])
998
999#------------------------------------------------------------------------
1000# MP_CHECK_READLINK_IS_P1003_1A --
1001#
1002#       Check if readlink conforms to POSIX 1003.1a standard, define
1003#       READLINK_IS_NOT_P1003_1A if it doesn't.
1004#
1005# Arguments:
1006#       None.
1007#
1008# Requires:
1009#       None.
1010#
1011# Depends:
1012#               AC_LANG_PROGRAM
1013#
1014# Results:
1015#       Result is cached.
1016#
1017#       If readlink doesn't conform to POSIX 1003.1a, defines the following variables:
1018#               READLINK_IS_NOT_P1003_1A
1019#
1020#------------------------------------------------------------------------
1021AC_DEFUN(MP_CHECK_READLINK_IS_P1003_1A, [
1022        AC_MSG_CHECKING([if readlink conforms to POSIX 1003.1a])
1023
1024        AC_CACHE_VAL(mp_cv_readlink_is_posix_1003_1a, [
1025                AC_COMPILE_IFELSE([
1026                        AC_LANG_PROGRAM([
1027                                        #include <unistd.h>
1028                                        ssize_t readlink(const char *, char *, size_t);
1029                                ], [
1030                        ])
1031                        ], [
1032                                mp_cv_readlink_is_posix_1003_1a="yes"
1033                        ], [
1034                                mp_cv_readlink_is_posix_1003_1a="no"
1035                        ]
1036                )
1037        ])
1038
1039        AC_MSG_RESULT(${mp_cv_readlink_is_posix_1003_1a})
1040
1041        if test x"${mp_cv_readlink_is_posix_1003_1a}" = "xno"; then
1042                AC_DEFINE([READLINK_IS_NOT_P1003_1A], [], [Define to 1 if readlink does not conform with POSIX 1003.1a (where third argument is a size_t and return value is a ssize_t)])
1043        fi
1044
1045        AC_SUBST(READLINK_IS_NOT_P1003_1A)
1046])
1047
1048#------------------------------------------------------------------------
1049# MP_WERROR --
1050#
1051#       Enable -Werror
1052#
1053# Arguments:
1054#       None.
1055#
1056# Requires:
1057#       none
1058#
1059# Depends:
1060#       none
1061#
1062# Results:
1063#       Substitutes WERROR_CFLAGS variable
1064#------------------------------------------------------------------------
1065AC_DEFUN([MP_WERROR],[
1066        AC_REQUIRE([AC_PROG_CC])
1067        AC_ARG_ENABLE(werror, AS_HELP_STRING([--enable-werror],[Add -Werror to CFLAGS. Used for development.]), [enable_werror=${enableval}], [enable_werror=no])
1068        if test x"$enable_werror" != "xno"; then
1069                CFLAGS_WERROR="-Werror"
1070        else
1071                CFLAGS_WERROR=""
1072        fi
1073        AC_SUBST([CFLAGS_WERROR])
1074])
1075
1076#------------------------------------------------------------------------
1077# MP_CHECK_SQLITE_VERSION --
1078#
1079#       Check for a specific SQLite version and execute commands depending on availability
1080#
1081# Arguments:
1082#       Required SQLite version for the test to succeed in the form of SQLITE_VERSION_NUMBER
1083#
1084# Requires:
1085#       MP_SQLITE3_FLAGS
1086#
1087# Depends:
1088#               AC_LANG_SOURCE
1089#
1090# Results:
1091#               Result is cached.
1092#
1093#       sets mp_sqlite_version_ge_$1 to yes or no
1094#
1095#------------------------------------------------------------------------
1096AC_DEFUN(MP_CHECK_SQLITE_VERSION, [
1097        AC_REQUIRE([MP_SQLITE3_FLAGS])
1098
1099        AC_MSG_CHECKING([for SQLite >= $1])
1100
1101        mp_check_sqlite_version_cppflags_save=$CPPFLAGS
1102        CPPFLAGS="$CPPFLAGS $CFLAGS_SQLITE3"
1103
1104        AC_CACHE_VAL(mp_cv_sqlite_version_defined, [
1105                AC_PREPROC_IFELSE(
1106                        [AC_LANG_SOURCE(
1107                                [[
1108                                        #include <sqlite3.h>
1109                                        #ifndef SQLITE_VERSION_NUMBER
1110                                        #  error "SQLITE_VERSION_NUMBER undefined"
1111                                        #endif
1112                                ]]
1113                        )],
1114                        [mp_cv_sqlite_version_defined="yes"],
1115                        [AC_MSG_ERROR("SQLITE_VERSION_NUMBER undefined or sqlite3.h not found")]
1116                )
1117        ])
1118
1119        if test x"${mp_cv_sqlite_version_defined}" = "xno"; then
1120                AC_MSG_RESULT([SQLite version not found])
1121                mp_sqlite_version_ge_$1="no"
1122        else
1123                AC_CACHE_VAL(mp_cv_sqlite_version_ge_$1, [
1124                        AC_PREPROC_IFELSE(
1125                                [AC_LANG_SOURCE(
1126                                        [[
1127                                                #include <sqlite3.h>
1128                                                #if (SQLITE_VERSION_NUMBER >= $1)
1129                                                /* Everything is fine */
1130                                                #else
1131                                                #  error "SQLite version too old"
1132                                                #endif
1133                                        ]]
1134                                )],
1135                                [mp_cv_sqlite_version_ge_$1="yes"],
1136                                [mp_cv_sqlite_version_ge_$1="no"]
1137                        )
1138                ])
1139
1140                AC_MSG_RESULT(${mp_cv_sqlite_version_ge_$1})
1141                mp_sqlite_version_ge_$1=${mp_cv_sqlite_version_ge_$1}
1142        fi
1143
1144        CPPFLAGS=$mp_check_sqlite_version_cppflags_save
1145])
1146
Note: See TracBrowser for help on using the repository browser.