source: trunk/base/aclocal.m4 @ 46954

Last change on this file since 46954 was 46954, checked in by jmr@…, 11 years ago

Merge gsoc08-privileges branch into trunk.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 29.2 KB
Line 
1dnl $Id: aclocal.m4 46954 2009-02-18 09:32:43Z jmr@macports.org $
2builtin(include,m4/tcl.m4)
3builtin(include,m4/objc.m4)
4builtin(include,m4/pthread.m4)
5builtin(include,m4/foundation.m4)
6
7#------------------------------------------------------------------------
8# MP_CHECK_FRAMEWORK_COREFOUNDATION --
9#
10#       Check if CoreFoundation framework is available, define HAVE_FRAMEWORK_COREFOUNDATION if so.
11#
12# Arguments:
13#       None.
14#
15# Requires:
16#       None.
17#
18# Depends:
19#               AC_LANG_PROGRAM
20#
21# Results:
22#       Result is cached.
23#
24#       If CoreFoundation framework is available, defines the following variables:
25#               HAVE_FRAMEWORK_COREFOUNDATION
26#
27#------------------------------------------------------------------------
28AC_DEFUN(MP_CHECK_FRAMEWORK_COREFOUNDATION, [
29        FRAMEWORK_LIBS="-framework CoreFoundation"
30
31        AC_MSG_CHECKING([for CoreFoundation framework])
32
33        AC_CACHE_VAL(mp_cv_have_framework_corefoundation, [
34                ac_save_LIBS="$LIBS"
35                LIBS="$FRAMEWORK_LIBS $LIBS"
36               
37                AC_LINK_IFELSE([
38                        AC_LANG_PROGRAM([
39                                        #include <CoreFoundation/CoreFoundation.h>
40                                ], [
41                                        CFURLRef url = CFURLCreateWithFileSystemPath(NULL, CFSTR("/testing"), kCFURLPOSIXPathStyle, 1);
42                                        CFArrayRef bundles = CFBundleCreateBundlesFromDirectory(NULL, url, CFSTR("pkg"));
43                        ])
44                        ], [
45                                mp_cv_have_framework_corefoundation="yes"
46                        ], [
47                                mp_cv_have_framework_corefoundation="no"
48                        ]
49                )
50
51                LIBS="$ac_save_LIBS"
52        ])
53
54        AC_MSG_RESULT(${mp_cv_have_framework_corefoundation})
55
56        if test x"${mp_cv_have_framework_corefoundation}" = "xyes"; then
57                AC_DEFINE([HAVE_FRAMEWORK_COREFOUNDATION], [], [Define if CoreFoundation framework is available])
58        fi
59
60        AC_SUBST(HAVE_FRAMEWORK_COREFOUNDATION)
61])
62
63
64#------------------------------------------------------------------------
65# MP_CHECK_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER --
66#
67#       Check if if the routine CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER
68#       is available in CoreFoundation.
69#
70# Arguments:
71#       None.
72#
73# Requires:
74#       None.
75#
76# Depends:
77#               AC_LANG_PROGRAM
78#
79# Results:
80#       Result is cached.
81#
82#       If function CFNotificationCenterGetDarwinNotifyCenter is in the CoreFoundation framework, defines the following variables:
83#               HAVE_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER
84#
85#------------------------------------------------------------------------
86AC_DEFUN(MP_CHECK_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER, [
87        FRAMEWORK_LIBS="-framework CoreFoundation"
88
89        AC_MSG_CHECKING([for CFNotificationCenterGetDarwinNotifyCenter])
90
91        AC_CACHE_VAL(mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter, [
92                ac_save_LIBS="$LIBS"
93                LIBS="$FRAMEWORK_LIBS $LIBS"
94               
95                AC_LINK_IFELSE([
96                        AC_LANG_PROGRAM([
97                                        #include <CoreFoundation/CoreFoundation.h>
98                                ], [
99                                        CFNotificationCenterRef ref = CFNotificationCenterGetDarwinNotifyCenter();
100                        ])
101                        ], [
102                                mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter="yes"
103                        ], [
104                                mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter="no"
105                        ]
106                )
107
108                LIBS="$ac_save_LIBS"
109        ])
110
111        AC_MSG_RESULT(${mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter})
112
113        if test x"${mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter}" = "xyes"; then
114                AC_DEFINE([HAVE_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER], [], [Define if function CFNotificationCenterGetDarwinNotifyCenter in CoreFoundation framework])
115        fi
116
117        AC_SUBST(HAVE_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER)
118])
119
120
121#------------------------------------------------------------------------
122# MP_CHECK_FRAMEWORK_SYSTEMCONFIGURATION --
123#
124#       Check if SystemConfiguration framework is available, define HAVE_FRAMEWORK_SYSTEMCONFIGURATION if so.
125#
126# Arguments:
127#       None.
128#
129# Requires:
130#       None.
131#
132# Depends:
133#               AC_LANG_PROGRAM
134#
135# Results:
136#       Result is cached.
137#
138#       If SystemConfiguration framework is available, defines the following variables:
139#               HAVE_FRAMEWORK_SYSTEMCONFIGURATION
140#
141#------------------------------------------------------------------------
142AC_DEFUN(MP_CHECK_FRAMEWORK_SYSTEMCONFIGURATION, [
143        FRAMEWORK_LIBS="-framework SystemConfiguration"
144
145        AC_MSG_CHECKING([for SystemConfiguration framework])
146
147        AC_CACHE_VAL(mp_cv_have_framework_systemconfiguration, [
148                ac_save_LIBS="$LIBS"
149                LIBS="$FRAMEWORK_LIBS $LIBS"
150               
151                AC_LINK_IFELSE([
152                        AC_LANG_PROGRAM([
153                                        #include <SystemConfiguration/SystemConfiguration.h>
154                                ], [
155                                        int err = SCError();
156                                        SCDynamicStoreRef dsRef = SCDynamicStoreCreate(NULL, NULL, NULL, NULL);
157                        ])
158                        ], [
159                                mp_cv_have_framework_systemconfiguration="yes"
160                        ], [
161                                mp_cv_have_framework_systemconfiguration="no"
162                        ]
163                )
164
165                LIBS="$ac_save_LIBS"
166        ])
167
168        AC_MSG_RESULT(${mp_cv_have_framework_systemconfiguration})
169
170        if test x"${mp_cv_have_framework_systemconfiguration}" = "xyes"; then
171                AC_DEFINE([HAVE_FRAMEWORK_SYSTEMCONFIGURATION], [], [Define if SystemConfiguration framework is available])
172        fi
173
174        AC_SUBST(HAVE_FRAMEWORK_SYSTEMCONFIGURATION)
175])
176
177
178#------------------------------------------------------------------------
179# MP_CHECK_FRAMEWORK_IOKIT --
180#
181#       Check if IOKit framework is available, define HAVE_FRAMEWORK_IOKIT if so.
182#
183# Arguments:
184#       None.
185#
186# Requires:
187#       None.
188#
189# Depends:
190#               AC_LANG_PROGRAM
191#
192# Results:
193#       Result is cached.
194#
195#       If IOKit framework is available, defines the following variables:
196#               HAVE_FRAMEWORK_IOKIT
197#
198#------------------------------------------------------------------------
199AC_DEFUN(MP_CHECK_FRAMEWORK_IOKIT, [
200        FRAMEWORK_LIBS="-framework IOKit"
201
202        AC_MSG_CHECKING([for IOKit framework])
203
204        AC_CACHE_VAL(mp_cv_have_framework_iokit, [
205                ac_save_LIBS="$LIBS"
206                LIBS="$FRAMEWORK_LIBS $LIBS"
207               
208                AC_LINK_IFELSE([
209                        AC_LANG_PROGRAM([
210                                        #include <IOKit/IOKitLib.h>
211                                ], [
212                                        IOCreateReceivePort(0, NULL);
213                                        IORegisterForSystemPower(0, NULL, NULL, NULL);
214                        ])
215                        ], [
216                                mp_cv_have_framework_iokit="yes"
217                        ], [
218                                mp_cv_have_framework_iokit="no"
219                        ]
220                )
221
222                LIBS="$ac_save_LIBS"
223        ])
224
225        AC_MSG_RESULT(${mp_cv_have_framework_iokit})
226
227        if test x"${mp_cv_have_framework_iokit}" = "xyes"; then
228                AC_DEFINE([HAVE_FRAMEWORK_IOKIT], [], [Define if IOKit framework is available])
229        fi
230
231        AC_SUBST(HAVE_FRAMEWORK_IOKIT)
232])
233
234
235dnl This macro checks if the user specified a ports tree
236dnl explicitly. If not, search for it
237
238# MP_PATH_PORTSDIR(DEFAULT_PORTSDIR)
239#---------------------------------------
240 AC_DEFUN([MP_PATH_PORTSDIR],[
241        dnl For ease of reading, run after gcc has been found/configured
242        AC_REQUIRE([AC_PROG_CC])
243
244        AC_ARG_WITH(ports-dir, [AC_HELP_STRING([--with-ports-dir=DIR], [Specify alternate ports directory])], [ portsdir="$withval" ] )
245
246
247        AC_MSG_CHECKING([for ports tree])
248        if test "x$portsdir" != "x" ; then
249          if test -d "$portsdir" -a -e "$portsdir/PortIndex" ; then
250                :
251          else
252                AC_MSG_ERROR([$portsdir not a valid ports tree])
253          fi
254        else
255                dnl If the user didn't give a path, look for default
256                if test "x$1" != "x" ; then
257                  if test -d "$1" -a -e "$1/PortIndex" ; then
258                        portsdir=$1
259                  fi
260                fi
261        fi
262
263        if test "x$portsdir" != "x" ; then
264                AC_MSG_RESULT($portsdir)
265                PORTSDIR="$portsdir"
266                AC_SUBST(PORTSDIR)
267        else
268                AC_MSG_WARN([No ports tree found])
269        fi
270
271         ])
272
273
274# MP_PATH_MPCONFIGDIR
275#---------------------------------------
276AC_DEFUN([MP_PATH_MPCONFIGDIR],[
277        dnl if the user actually specified --prefix, shift
278        dnl mpconfigdir to $prefix/etc/macports
279        dnl     AC_REQUIRE([MP_PATH_PORTSDIR])
280       
281        AC_MSG_CHECKING([for MacPorts config directory])
282
283        mpconfigdir='${sysconfdir}/macports'
284
285        AC_MSG_RESULT([$mpconfigdir])
286        MPCONFIGDIR="$mpconfigdir"
287        AC_SUBST(MPCONFIGDIR)
288
289        ])
290
291
292# MP_CHECK_NOROOTPRIVILEGES
293#-------------------------------------------------
294AC_DEFUN([MP_CHECK_NOROOTPRIVILEGES],[
295        dnl if with user specifies --with-no-root-privileges,
296        dnl use current user and group.
297        dnl use ~/Library/Tcl as Tcl package directory
298                AC_REQUIRE([MP_PATH_MPCONFIGDIR])
299
300        AC_ARG_WITH(no-root-privileges, [AC_HELP_STRING([--with-no-root-privileges], [Specify that MacPorts should be installed in your home directory])], [ROOTPRIVS=$withval] )
301
302        if test "${ROOTPRIVS+set}" = set; then
303
304                # Set install-user to current user
305                AC_MSG_CHECKING([for install user])
306                DSTUSR=`id -un`
307                AC_MSG_RESULT([$DSTUSR])
308                AC_SUBST(DSTUSR)
309               
310                # Set install-group to current user
311                AC_MSG_CHECKING([for install group])
312                DSTGRP=`id -gn`
313                AC_MSG_RESULT([$DSTGRP])
314                AC_SUBST(DSTGRP)
315
316                # Set Tcl package directory to ~/Library/Tcl
317            AC_MSG_CHECKING(for Tcl package directory)
318                ac_cv_c_tclpkgd="~$DSTUSR/Library/Tcl"
319            # Convert to a native path and substitute into the output files.
320            PACKAGE_DIR_NATIVE=`${CYGPATH} ${ac_cv_c_tclpkgd}`
321            TCL_PACKAGE_DIR=${PACKAGE_DIR_NATIVE}
322            AC_SUBST(TCL_PACKAGE_DIR)
323                if test x"${ac_cv_c_tclpkgd}" = x ; then
324                        AC_MSG_ERROR(Tcl package directory not found.  Please specify its location with --with-tclpackage)
325            else
326                        AC_MSG_RESULT(${ac_cv_c_tclpkgd})
327            fi
328        fi
329
330])
331
332# MP_CHECK_RUNUSER
333#-------------------------------------------------
334AC_DEFUN([MP_CHECK_RUNUSER],[
335        dnl if with user specifies --with-macports-user,
336        dnl use it. otherwise default to platform defaults
337       AC_REQUIRE([MP_PATH_MPCONFIGDIR])
338
339        AC_ARG_WITH(macports-user, [AC_HELP_STRING([--with-macports-user=USER], [Specify user to drop privileges to, if possible, during compiles etc.])], [ RUNUSR=$withval ] )
340       
341        AC_MSG_CHECKING([for macports user])
342        if test "x$RUNUSR" = "x" ; then
343# dropping root privs is still buggy
344#          RUNUSR=`id -un`
345           RUNUSR=root
346        fi
347
348        AC_MSG_RESULT([$RUNUSR])
349        AC_SUBST(RUNUSR)
350])
351
352
353# MP_SHARED_DIRECTORY
354#-------------------------------------------------
355AC_DEFUN([MP_SHARED_DIRECTORY],[
356        dnl if with user specifies --with-shared-directory,
357        dnl use 0775 permissions for ${prefix} directories
358        AC_REQUIRE([MP_PATH_MPCONFIGDIR])
359
360        AC_ARG_WITH(shared-directory, [AC_HELP_STRING([--with-shared-directory], [Use 0775 permissions for installed directories])], [ SHAREDIR=$withval ] )
361
362        if test "${SHAREDIR+set}" = set; then   
363                AC_MSG_CHECKING([whether to share the install directory with all members of the install group])
364            DSTMODE=0775
365
366                AC_MSG_RESULT([$DSTMODE])
367                AC_SUBST(DSTMODE)
368        fi
369])
370
371# MP_CHECK_INSTALLUSER
372#-------------------------------------------------
373AC_DEFUN([MP_CHECK_INSTALLUSER],[
374        dnl if with user specifies --with-install-user,
375        dnl use it. otherwise default to platform defaults
376        AC_REQUIRE([MP_PATH_MPCONFIGDIR])
377
378        AC_ARG_WITH(install-user, [AC_HELP_STRING([--with-install-user=USER], [Specify user ownership of installed files])], [ DSTUSR=$withval ] )
379       
380        AC_MSG_CHECKING([for install user])
381        if test "x$DSTUSR" = "x" ; then
382           DSTUSR=root
383        fi
384
385        AC_MSG_RESULT([$DSTUSR])
386        AC_SUBST(DSTUSR)
387])
388
389# MP_CHECK_INSTALLGROUP
390#-------------------------------------------------
391AC_DEFUN([MP_CHECK_INSTALLGROUP],[
392        dnl if with user specifies --with-install-group,
393        dnl use it. otherwise default to platform defaults
394        AC_REQUIRE([MP_CHECK_INSTALLUSER])
395
396        AC_ARG_WITH(install-group, [AC_HELP_STRING([--with-install-group=GROUP], [Specify group ownership of installed files])], [ DSTGRP=$withval ] )
397
398        AC_MSG_CHECKING([for install group])
399        if test "x$DSTGRP" = "x" ; then
400           
401           case $host_os in
402           darwin*)
403                DSTGRP="admin"
404                ;;
405           freebsd*)
406                DSTGRP="wheel"
407                ;;
408           linux*)
409                DSTGRP="root"
410                ;;
411           *)
412                DSTGRP="wheel"
413                ;;
414           esac
415        fi
416
417        AC_MSG_RESULT([$DSTGRP])
418        AC_SUBST(DSTGRP)
419])
420
421# MP_DIRECTORY_MODE
422#-------------------------------------------------
423AC_DEFUN([MP_DIRECTORY_MODE],[
424        dnl if with user specifies --with-directory-mode,
425        dnl use the specified permissions for ${prefix} directories
426        dnl otherwise use 0755
427        AC_REQUIRE([MP_PATH_MPCONFIGDIR])
428
429        AC_ARG_WITH(directory-mode, [AC_HELP_STRING([--with-directory-mode=MODE], [Specify directory mode of installed directories])], [ DSTMODE=$withval ] )
430       
431        AC_MSG_CHECKING([what permissions to use for installation directories])
432        if test "x$DSTMODE" = "x" ; then
433           DSTMODE=0755
434        fi
435
436        AC_MSG_RESULT([$DSTMODE])
437        AC_SUBST(DSTMODE)
438])
439
440# MP_PATH_APPLICATIONS
441#---------------------------------------
442AC_DEFUN([MP_PATH_APPLICATIONS],[
443        AC_REQUIRE([MP_CHECK_INSTALLUSER])
444
445    AC_ARG_WITH(applications-dir,[AC_HELP_STRING([--with-applications-dir], [Applications installation directory.])], MPAPPLICATIONSDIR=${withval})
446
447    oldprefix=$prefix
448    if test "x$prefix" = "xNONE" ; then
449        prefix=$ac_default_prefix
450    fi
451    AC_MSG_CHECKING([for Applications installation directory])
452
453        if test "x$MPAPPLICATIONSDIR" = "x" ; then
454            if test "$DSTUSR" = "root" ; then
455                MPAPPLICATIONSDIR="/Applications/MacPorts"
456            else
457                MPAPPLICATIONSDIR="~$DSTUSR/Applications/MacPorts"
458            fi
459        fi
460
461        AC_MSG_RESULT([$MPAPPLICATIONSDIR])
462    AC_SUBST(MPAPPLICATIONSDIR)
463    prefix=$oldprefix
464])
465
466# MP_PATH_FRAMEWORKS
467#---------------------------------------
468AC_DEFUN([MP_PATH_FRAMEWORKS],[
469        AC_REQUIRE([MP_CHECK_INSTALLUSER])
470
471    AC_ARG_WITH(frameworks-dir,[AC_HELP_STRING([--with-frameworks-dir], [Frameworks installation directory.])], MPFRAMEWORKSDIR=${withval})
472
473    oldprefix=$prefix
474    if test "x$prefix" = "xNONE" ; then
475        prefix=$ac_default_prefix
476    fi
477    AC_MSG_CHECKING([for Frameworks installation directory])
478
479        if test "x$MPFRAMEWORKSDIR" = "x" ; then
480                MPFRAMEWORKSDIR="${prefix}/Library/Frameworks"
481        fi
482
483        AC_MSG_RESULT([$MPFRAMEWORKSDIR])
484    AC_SUBST(MPFRAMEWORKSDIR)
485    prefix=$oldprefix
486])
487
488
489# MP_UNIVERSAL_OPTIONS
490#---------------------------------------
491AC_DEFUN([MP_UNIVERSAL_OPTIONS],[
492
493    AC_ARG_WITH(universal-target,[AC_HELP_STRING([--with-universal-target=MDT], [Universal MACOSX_DEPLOYMENT_TARGET version])], UNIVERSAL_TARGET=${withval})
494    AC_ARG_WITH(universal-sysroot,[AC_HELP_STRING([--with-universal-sysroot=SDK], [Universal SDK sysroot (with complete path)])], UNIVERSAL_SYSROOT=${withval})
495    AC_ARG_WITH(universal-archs,[AC_HELP_STRING([--with-universal-archs="CPU"], [Universal CPU architectures (space separated)])], UNIVERSAL_ARCHS=${withval})
496
497        if test "x$UNIVERSAL_TARGET" = "x"; then
498            if [test -d /Developer/SDKs/MacOSX10.5.sdk]; then
499                UNIVERSAL_TARGET=10.5
500                UNIVERSAL_SYSROOT=/Developer/SDKs/MacOSX10.5.sdk
501            else
502                UNIVERSAL_TARGET=10.4
503                UNIVERSAL_SYSROOT=/Developer/SDKs/MacOSX10.4u.sdk
504            fi
505        else
506            if test "x$UNIVERSAL_SYSROOT" = "x"; then
507                UNIVERSAL_SYSROOT=/Developer/SDKs/MacOSX${UNIVERSAL_TARGET}.sdk
508            fi
509        fi
510
511        if test "x$UNIVERSAL_ARCHS" = "x"; then
512                #UNIVERSAL_ARCHS="ppc ppc64 i386 x86_64"
513                UNIVERSAL_ARCHS="ppc i386"
514        fi
515   
516    AC_MSG_CHECKING([for Universal MDT version])
517    AC_MSG_RESULT([$UNIVERSAL_TARGET])
518    AC_SUBST(UNIVERSAL_TARGET)
519
520    AC_MSG_CHECKING([for Universal SDK sysroot])
521    AC_MSG_RESULT([$UNIVERSAL_SYSROOT])
522    AC_SUBST(UNIVERSAL_SYSROOT)
523
524    AC_MSG_CHECKING([for Universal CPU architectures])
525    AC_MSG_RESULT([$UNIVERSAL_ARCHS])
526    AC_SUBST(UNIVERSAL_ARCHS)
527])
528
529# MP_LIB_MD5
530#---------------------------------------
531# Check for an md5 implementation
532AC_DEFUN([MP_LIB_MD5],[
533
534        # Check for libmd, which is prefered
535        AC_CHECK_LIB([md], [MD5Update],[
536                AC_CHECK_HEADERS([md5.h], ,[
537                        case $host_os in
538                                darwin*)       
539                                        AC_MSG_NOTICE([Please install the BSD SDK package from the Xcode Developer Tools CD.])
540                                        ;;
541                                *)     
542                                        AC_MSG_NOTICE([Please install the libmd developer headers for your platform.])
543                                        ;;
544                        esac
545                        AC_MSG_ERROR([libmd was found, but md5.h is missing.])
546                ])
547                AC_DEFINE([HAVE_LIBMD], ,[Define if you have the `md' library (-lmd).])
548                MD5_LIBS="-lmd"]
549        )
550        if test "x$MD5_LIBS" = "x" ; then
551                # If libmd is not found, check for libcrypto from OpenSSL
552                AC_CHECK_LIB([crypto], [MD5_Update],[
553                        AC_CHECK_HEADERS([openssl/md5.h],,[
554                                case $host_os in
555                                        darwin*)       
556                                        AC_MSG_NOTICE([Please install the BSD SDK package from the Xcode Developer Tools CD.])
557                                                ;;
558                                        *)     
559                                        AC_MSG_NOTICE([Please install the libmd developer headers for your platform.])
560                                                ;;
561                                esac
562                                AC_MSG_ERROR([libcrypt was found, but header file openssl/md5.h is missing.])
563                        ])
564                        AC_DEFINE([HAVE_LIBCRYPTO],,[Define if you have the `crypto' library (-lcrypto).])
565                        MD5_LIBS="-lcrypto"
566                ], [
567                        AC_MSG_ERROR([Neither OpenSSL or libmd were found. A working md5 implementation is required.])
568                ])
569        fi
570        if test "x$MD5_LIBS" = "x"; then
571                AC_MSG_ERROR([Neither OpenSSL or libmd were found. A working md5 implementation is required.])
572        fi
573        AC_SUBST([MD5_LIBS])
574])
575
576dnl This macro checks for X11 presence. If the libraries are
577dnl present, so must the headers be. If nothing is present,
578dnl print a warning
579
580# MP_CHECK_X11
581# ---------------------
582AC_DEFUN([MP_CHECK_X11], [
583
584        # work around symbolic X11 link in /usr/include by providing explicit defaults
585        case "$host" in
586            *-*-darwin9*)
587                if test "x$x_includes" = xNONE && test "x$x_libraries" = xNONE; then
588                    x_includes="/usr/X11/include"
589                    x_libraries="/usr/X11/lib"
590                fi
591                ;;
592            *-*-darwin*)
593                if test "x$x_includes" = xNONE && test "x$x_libraries" = xNONE; then
594                    x_includes="/usr/X11R6/include"
595                    x_libraries="/usr/X11R6/lib"
596                fi
597                ;;
598        esac
599
600        AC_PATH_X
601        AC_PATH_XTRA
602
603        # Check for libX11
604        AC_CHECK_LIB([X11], [XOpenDisplay],[
605                has_x_runtime=yes
606                ], [ has_x_runtime=no ], [$X_LIBS])
607
608#       echo "------done---------"
609#       echo "x_includes=${x_includes}"
610#       echo "x_libraries=${x_libraries}"
611#       echo "no_x=${no_x}"
612#       echo "X_CFLAGS=${X_CFLAGS}"
613#       echo "X_LIBS=${X_LIBS}"
614#       echo "X_DISPLAY_MISSING=${X_DISPLAY_MISSING}"
615#       echo "has_x_runtime=${has_x_runtime}"
616#       echo "host_os=${host_os}"
617#       echo "------done---------"
618
619        state=
620
621        case "__${has_x_runtime}__${no_x}__" in
622                "__no__yes__")
623                # either the user said --without-x, or it was not found
624                # at all (runtime or headers)
625                        AC_MSG_WARN([X11 not available. You will not be able to use ports that use X11])
626                        state=0
627                        ;;
628                "__yes__yes__")
629                        state=1
630                        ;;
631                "__yes____")
632                        state=2
633                        ;;
634                *)
635                        state=3
636                        ;;
637        esac
638
639        case $host_os in
640                darwin*)       
641                        case $state in
642                                1)
643                                        cat <<EOF;
644Please install the X11 SDK packages from the
645Xcode Developer Tools CD
646EOF
647                                        AC_MSG_ERROR([Broken X11 install. No X11 headers])
648
649                                        ;;
650                                3)
651                                        cat <<EOF;
652Unknown configuration problem. Please install the X11 runtime
653and/or X11 SDK  packages from the Xcode Developer Tools CD
654EOF
655                                        AC_MSG_ERROR([Broken X11 install])
656                                        ;;
657                        esac
658                        ;;
659                *)     
660                        case $state in
661                                1)
662                                        cat <<EOF;
663Please install the X11 developer headers for your platform
664EOF
665                                        AC_MSG_ERROR([Broken X11 install. No X11 headers])
666
667                                        ;;
668                                3)
669                                        cat <<EOF;
670Unknown configuration problem. Please install the X11
671implementation for your platform
672EOF
673                                        AC_MSG_ERROR([Broken X11 install])
674                                        ;;
675                        esac
676                        ;;
677        esac
678
679])
680
681# MP_PROG_XAR
682#---------------------------------------
683AC_DEFUN([MP_PROG_XAR],[
684
685        AC_PATH_PROG([XAR], [xar], ,  [/usr/bin:/usr/sbin:/bin:/sbin])
686
687        if test "x$XAR" = "x" ; then
688                AC_CONFIG_SUBDIRS([src/programs/xar])
689                XAR='$(TOPSRCDIR)/src/programs/xar/xar'
690                REPLACEMENT_PROGS="$REPLACEMENT_PROGS xar"
691        fi
692
693        AC_SUBST(XAR)
694])
695
696# MP_PROG_DAEMONDO
697#---------------------------------------
698AC_DEFUN([MP_PROG_DAEMONDO],[
699        AC_REQUIRE([MP_CHECK_FRAMEWORK_COREFOUNDATION])
700        AC_REQUIRE([MP_CHECK_FRAMEWORK_SYSTEMCONFIGURATION])
701        AC_REQUIRE([MP_CHECK_FRAMEWORK_IOKIT])
702        AC_REQUIRE([MP_CHECK_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER])
703       
704    AC_MSG_CHECKING(for whether we will build daemondo)
705    result=no
706        case $host_os in
707        darwin*)
708                if test "x$mp_cv_have_framework_corefoundation" == "xyes" &&
709                   test "x$mp_cv_have_framework_systemconfiguration" == "xyes" &&
710                   test "x$mp_cv_have_framework_iokit" == "xyes" &&
711                   test "x$mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter" == "xyes"; then
712                        result=yes
713                        EXTRA_PROGS="$EXTRA_PROGS daemondo"
714                        AC_CONFIG_FILES([src/programs/daemondo/Makefile])
715                fi
716                ;;
717        *)
718        esac
719        AC_MSG_RESULT(${result})
720])
721
722#------------------------------------------------------------------------
723# MP_TCL_PACKAGE_DIR --
724#
725#       Locate the correct directory for Tcl package installation
726#
727# Arguments:
728#       None.
729#
730# Requires:
731#       TCLVERSION must be set
732#       CYGPATH must be set
733#       TCLSH must be set
734#
735# Results:
736#
737#       Adds a --with-tclpackage switch to configure.
738#       Result is cached.
739#
740#       Substs the following vars:
741#               TCL_PACKAGE_DIR
742#------------------------------------------------------------------------
743
744AC_DEFUN(MP_TCL_PACKAGE_DIR, [
745        AC_REQUIRE([MP_CHECK_INSTALLUSER])
746
747    AC_MSG_CHECKING(for Tcl package directory)
748
749    AC_ARG_WITH(tclpackage, [  --with-tclpackage       Tcl package installation directory.], with_tclpackagedir=${withval})
750
751    if test x"${with_tclpackagedir}" != x ; then
752        ac_cv_c_tclpkgd=${with_tclpackagedir}
753    else
754        AC_CACHE_VAL(ac_cv_c_tclpkgd, [
755            # Use the value from --with-tclpackage, if it was given
756
757            if test x"${with_tclpackagedir}" != x ; then
758                echo "tclpackagedir"
759                ac_cv_c_tclpkgd=${with_tclpackagedir}
760            else
761                # On darwin we can do some intelligent guessing
762                case $host_os in
763                    darwin*)
764                        tcl_autopath=`echo 'puts -nonewline \$auto_path' | $TCLSH`
765                        for path in $tcl_autopath; do
766                        if test "$DSTUSR" = "root" ; then
767                            if test "$path" = "/Library/Tcl"; then
768                                ac_cv_c_tclpkgd="$path"
769                                break
770                            fi
771                            if test "$path" = "/System/Library/Tcl"; then
772                                if test -d "$path"; then
773                                    ac_cv_c_tclpkgd="$path"
774                                    break
775                                fi
776                            fi
777                        elif test "$path" = "~/Library/Tcl"; then
778                            ac_cv_c_tclpkgd="~$DSTUSR/Library/Tcl"
779                            break
780                        fi
781                        done
782                    ;;
783                esac
784                if test x"${ac_cv_c_tclpkgd}" = x ; then
785                    # Fudge a path from the first entry in the auto_path
786                    tcl_pkgpath=`echo 'puts -nonewline [[lindex \$auto_path 0]]' | $TCLSH`
787                    if test -d "$tcl_pkgpath"; then
788                        ac_cv_c_tclpkgd="$tcl_pkgpath"
789                    fi
790                    # If the first entry does not exist, do nothing
791                fi
792            fi
793        ])
794    fi
795
796    if test x"${ac_cv_c_tclpkgd}" = x ; then
797        AC_MSG_ERROR(Tcl package directory not found.  Please specify its location with --with-tclpackage)
798    else
799        AC_MSG_RESULT(${ac_cv_c_tclpkgd})
800    fi
801
802    # Convert to a native path and substitute into the output files.
803
804    PACKAGE_DIR_NATIVE=`${CYGPATH} ${ac_cv_c_tclpkgd}`
805
806    TCL_PACKAGE_DIR=${PACKAGE_DIR_NATIVE}
807
808    AC_SUBST(TCL_PACKAGE_DIR)
809])
810
811# MP_PROG_TCLSH
812#---------------------------------------
813AC_DEFUN([MP_PROG_TCLSH],[
814
815
816        case $host_os in
817                freebsd*)
818                        # FreeBSD installs a dummy tclsh (annoying)
819                        # Look for a real versioned tclsh with threads first
820                        # Look for a real versioned tclsh without threads second
821                        AC_PATH_PROG([TCLSH], [tclsh${TCL_VERSION}-threads tclsh${TCL_VERSION} tclsh])
822                        ;;
823                *)
824                        # Otherwise, look for a non-versioned tclsh
825                        AC_PATH_PROG([TCLSH], [tclsh tclsh${TCL_VERSION}])
826                        ;;
827        esac
828        if test "x$TCLSH" = "x" ; then
829                AC_MSG_ERROR([Could not find tclsh])
830        fi
831
832        AC_SUBST(TCLSH)
833])
834
835# MP_TCL_PACKAGE
836#       Determine if a Tcl package is present.
837#
838# Arguments:
839#       Package name (may include the version)
840#
841# Syntax:
842#   MP_TCL_PACKAGE (package, [action-if-found], [action-if-not-found])
843#
844# Requires:
845#       TCLSH must be set
846#
847# Results:
848#       Execute action-if-found or action-if-not-found
849#---------------------------------------
850AC_DEFUN([MP_TCL_PACKAGE],[
851        AC_MSG_CHECKING([for Tcl $1 package])
852        package_present=`echo 'if {[[catch {package require $1}]]} {puts -nonewline 0} else {puts -nonewline 1}' | $TCLSH`
853        AS_IF([test "$package_present" = "1"], [$2], [$3])[]
854])
855
856# MP_TCL_THREAD_SUPPORT
857#       Determine if thread support is available in tclsh.
858#
859# Arguments:
860#       None.
861#
862# Requires:
863#       TCLSH must be set
864#
865# Results:
866#   Fails if thread support isn't available.
867#---------------------------------------
868AC_DEFUN([MP_TCL_THREAD_SUPPORT],[
869        AC_MSG_CHECKING([whether tclsh was compiled with threads])
870        tcl_threadenabled=`echo 'puts -nonewline [[info exists tcl_platform(threaded)]]' | $TCLSH`
871        if test "$tcl_threadenabled" = "1" ; then
872                AC_MSG_RESULT([yes])
873        else
874                AC_MSG_RESULT([no])
875                AC_MSG_ERROR([tcl wasn't compiled with threads enabled])
876        fi
877])
878
879# MP_LIBCURL_FLAGS
880#       Sets the flags to compile with libcurl.
881#
882# Arguments:
883#       None.
884#
885# Requires:
886#   curl-config or user parameters to define the flags.
887#
888# Results:
889#   defines some help strings.
890#   sets CFLAGS_LIBCURL and LDFLAGS_LIBCURL
891#---------------------------------------
892AC_DEFUN([MP_LIBCURL_FLAGS],[
893        AC_ARG_WITH(curlprefix,
894                   [  --with-curlprefix       base directory for the cURL install '/usr', '/usr/local',...],
895                   [  curlprefix=$withval ])
896
897        if test "x$curlprefix" = "x"; then
898                AC_PATH_PROG([CURL_CONFIG], [curl-config])
899        else
900                AC_PATH_PROG([CURL_CONFIG], [curl-config], , [$curlprefix/bin])
901        fi
902
903        if test "x$CURL_CONFIG" = "x"; then
904                AC_MSG_ERROR([cannot find curl-config. Is libcurl installed?])
905        fi
906
907        CFLAGS_LIBCURL=$($CURL_CONFIG --cflags)
908        # Due to a bug in dist, --arch flags are improperly supplied by curl-config.
909        # Get rid of them.
910        LDFLAGS_LIBCURL=$($CURL_CONFIG --libs | [sed 's/-arch [A-Za-z0-9_]* //g'])
911
912        AC_SUBST(CFLAGS_LIBCURL)
913        AC_SUBST(LDFLAGS_LIBCURL)
914])
915
916# MP_LIBCURL_VERSION
917#       Determine the version of libcurl.
918#
919# Arguments:
920#       None.
921#
922# Requires:
923#       CURL must be set (AC_PATH_PROG(CURL, [curl], []))
924#
925# Results:
926#   sets libcurl_version to "0" or some number
927#---------------------------------------
928AC_DEFUN([MP_LIBCURL_VERSION],[
929        if test "x$CURL" = "x"; then
930                libcurl_version="0"
931        else
932                AC_MSG_CHECKING([libcurl version])
933                libcurl_version=`$CURL -V | sed '2,$d' | awk '{print $ 2}' | sed -e 's/\.//g' -e 's/-.*//g'`
934                AC_MSG_RESULT([$libcurl_version])
935        fi
936])
937
938
939dnl This macro tests if the compiler supports GCC's
940dnl __attribute__ syntax for unused variables/parameters
941AC_DEFUN([MP_COMPILER_ATTRIBUTE_UNUSED], [
942        AC_MSG_CHECKING([how to mark unused variables])
943        AC_COMPILE_IFELSE(
944                [AC_LANG_SOURCE([[int a __attribute__ ((unused));]])],
945                [AC_DEFINE(UNUSED, [__attribute__((unused))], [Attribute to mark unused variables])],
946                [AC_DEFINE(UNUSED, [])])
947
948        AC_MSG_RESULT([])
949       
950])
951
952dnl This macro ensures MP installation prefix bin/sbin paths are NOT in PATH
953dnl for configure to prevent potential problems when base/ code is updated
954dnl and ports are installed that would match needed items.
955AC_DEFUN([MP_PATH_SCAN],[
956        oldprefix=$prefix
957        if test "x$prefix" = "xNONE" ; then
958                prefix=$ac_default_prefix
959        fi
960        oldPATH=$PATH
961        newPATH=
962        as_save_IFS=$IFS; IFS=$PATH_SEPARATOR
963        for as_dir in $oldPATH
964        do
965                IFS=$as_save_IFS
966                if test "x$as_dir" != "x$prefix/bin" &&
967                        test "x$as_dir" != "x$prefix/sbin"; then
968                        if test -z "$newPATH"; then
969                                newPATH=$as_dir
970                        else
971                                newPATH=$newPATH$PATH_SEPARATOR$as_dir
972                        fi
973                fi
974        done
975        PATH=$newPATH; export PATH
976        prefix=$oldprefix
977])
978
979dnl This macro tests for sed support of -E (BSD) or -r (GNU)
980AC_DEFUN([MP_SED_EXTENDED_REGEXP],[
981        AC_PATH_PROG(SED, [sed])
982
983        if test "x$SED" = "x"; then
984                AC_MSG_ERROR([cannot find sed. Is sed installed?])
985        fi
986
987        AC_MSG_CHECKING([which sed flag to use for extended regexp])
988        [any_sed_flag=`echo foo | $SED    -e s/foo+/OK/ 2>&1 | grep OK`]
989        [bsd_sed_flag=`echo foo | $SED -E -e s/foo+/OK/ 2>&1 | grep OK`]
990        [gnu_sed_flag=`echo foo | $SED -r -e s/foo+/OK/ 2>&1 | grep OK`]
991        if test "x$any_sed_flag" = "xOK" ; then
992                AC_MSG_RESULT([none])
993                SED_EXT=
994        elif test "x$bsd_sed_flag" = "xOK" ; then
995                AC_MSG_RESULT([-E (BSD)])
996                SED_EXT=-E
997        elif test "x$gnu_sed_flag" = "xOK" ; then
998                AC_MSG_RESULT([-r (GNU)])
999                SED_EXT=-r
1000        else
1001                AC_MSG_RESULT([not available])
1002                SED_EXT='N/A'
1003        fi
1004        AC_SUBST(SED_EXT)
1005])
1006
1007dnl This macro tests for tar support of --no-same-owner
1008AC_DEFUN([MP_TAR_NO_SAME_OWNER],[
1009        AC_PATH_PROG(TAR, [tar])
1010        AC_PATH_PROG(GNUTAR, [gnutar])
1011       
1012        AC_MSG_CHECKING([for which tar variant to use])
1013        AS_IF([test -n "$GNUTAR"], [TAR_CMD=$GNUTAR], [TAR_CMD=$TAR])
1014        AC_MSG_RESULT([$TAR_CMD])
1015        AC_SUBST(TAR_CMD)
1016
1017        AC_MSG_CHECKING([for $TAR_CMD --no-same-owner support])
1018        [no_same_owner_support=`$TAR_CMD --help 2>&1 | grep no-same-owner`]
1019        if test -z "$no_same_owner_support" ; then
1020                AC_MSG_RESULT([no])
1021        else
1022                AC_MSG_RESULT([yes])
1023                TAR_CMD="$TAR_CMD --no-same-owner"
1024        fi
1025])
1026
1027#------------------------------------------------------------------------
1028# MP_CHECK_READLINK_IS_P1003_1A --
1029#
1030#       Check if readlink conforms to POSIX 1003.1a standard, define
1031#       READLINK_IS_NOT_P1003_1A if it doesn't.
1032#
1033# Arguments:
1034#       None.
1035#
1036# Requires:
1037#       None.
1038#
1039# Depends:
1040#               AC_LANG_PROGRAM
1041#
1042# Results:
1043#       Result is cached.
1044#
1045#       If readlink doesn't conform to POSIX 1003.1a, defines the following variables:
1046#               READLINK_IS_NOT_P1003_1A
1047#
1048#------------------------------------------------------------------------
1049AC_DEFUN(MP_CHECK_READLINK_IS_P1003_1A, [
1050        AC_MSG_CHECKING([if readlink conforms to POSIX 1003.1a])
1051
1052        AC_CACHE_VAL(mp_cv_readlink_is_posix_1003_1a, [
1053                AC_COMPILE_IFELSE([
1054                        AC_LANG_PROGRAM([
1055                                        #include <unistd.h>
1056                                        ssize_t readlink(const char *, char *, size_t);
1057                                ], [
1058                        ])
1059                        ], [
1060                                mp_cv_readlink_is_posix_1003_1a="yes"
1061                        ], [
1062                                mp_cv_readlink_is_posix_1003_1a="no"
1063                        ]
1064                )
1065        ])
1066
1067        AC_MSG_RESULT(${mp_cv_readlink_is_posix_1003_1a})
1068
1069        if test x"${mp_cv_readlink_is_posix_1003_1a}" = "xno"; then
1070                AC_DEFINE([READLINK_IS_NOT_P1003_1A], [], [Define to 1 if readlink does not conform with POSIX 1003.1a (where third argument is a size_t and return value is a ssize_t)])
1071        fi
1072
1073        AC_SUBST(READLINK_IS_NOT_P1003_1A)
1074])
1075
1076#------------------------------------------------------------------------
1077# MP_WERROR --
1078#
1079#       Enable -Werror
1080#
1081# Arguments:
1082#       None.
1083#
1084# Requires:
1085#       none
1086#
1087# Depends:
1088#       none
1089#
1090# Results:
1091#       Substitutes WERROR_CFLAGS variable
1092#------------------------------------------------------------------------
1093AC_DEFUN([MP_WERROR],[
1094        AC_REQUIRE([AC_PROG_CC])
1095        AC_ARG_ENABLE(werror, AC_HELP_STRING([--enable-werror], [Add -Werror to CFLAGS. Used for development.]), [enable_werror=${enableval}], [enable_werror=no])
1096        if test x"$enable_werror" != "xno"; then
1097                CFLAGS_WERROR="-Werror"
1098        else
1099                CFLAGS_WERROR=""
1100        fi
1101        AC_SUBST([CFLAGS_WERROR])
1102])
Note: See TracBrowser for help on using the repository browser.