source: trunk/base/aclocal.m4 @ 77749

Last change on this file since 77749 was 77749, checked in by afb@…, 9 years ago

autoconf: check for tar -q

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 28.2 KB
Line 
1dnl $Id: aclocal.m4 77749 2011-04-11 08:50:59Z afb@macports.org $
2builtin(include,m4/tcl.m4)
3builtin(include,m4/pthread.m4)
4builtin(include,m4/foundation.m4)
5
6#------------------------------------------------------------------------
7# MP_CHECK_FRAMEWORK_COREFOUNDATION --
8#
9#       Check if CoreFoundation framework is available, define HAVE_FRAMEWORK_COREFOUNDATION if so.
10#
11# Arguments:
12#       None.
13#
14# Requires:
15#       None.
16#
17# Depends:
18#               AC_LANG_PROGRAM
19#
20# Results:
21#       Result is cached.
22#
23#       If CoreFoundation framework is available, defines the following variables:
24#               HAVE_FRAMEWORK_COREFOUNDATION
25#
26#------------------------------------------------------------------------
27AC_DEFUN(MP_CHECK_FRAMEWORK_COREFOUNDATION, [
28        FRAMEWORK_LIBS="-framework CoreFoundation"
29
30        AC_MSG_CHECKING([for CoreFoundation framework])
31
32        AC_CACHE_VAL(mp_cv_have_framework_corefoundation, [
33                ac_save_LIBS="$LIBS"
34                LIBS="$FRAMEWORK_LIBS $LIBS"
35               
36                AC_LINK_IFELSE([
37                        AC_LANG_PROGRAM([
38                                        #include <CoreFoundation/CoreFoundation.h>
39                                ], [
40                                        CFURLRef url = CFURLCreateWithFileSystemPath(NULL, CFSTR("/testing"), kCFURLPOSIXPathStyle, 1);
41                                        CFArrayRef bundles = CFBundleCreateBundlesFromDirectory(NULL, url, CFSTR("pkg"));
42                        ])
43                        ], [
44                                mp_cv_have_framework_corefoundation="yes"
45                        ], [
46                                mp_cv_have_framework_corefoundation="no"
47                        ]
48                )
49
50                LIBS="$ac_save_LIBS"
51        ])
52
53        AC_MSG_RESULT(${mp_cv_have_framework_corefoundation})
54
55        if test x"${mp_cv_have_framework_corefoundation}" = "xyes"; then
56                AC_DEFINE([HAVE_FRAMEWORK_COREFOUNDATION], [], [Define if CoreFoundation framework is available])
57        fi
58
59        AC_SUBST(HAVE_FRAMEWORK_COREFOUNDATION)
60])
61
62
63#------------------------------------------------------------------------
64# MP_CHECK_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER --
65#
66#       Check if if the routine CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER
67#       is available in CoreFoundation.
68#
69# Arguments:
70#       None.
71#
72# Requires:
73#       None.
74#
75# Depends:
76#               AC_LANG_PROGRAM
77#
78# Results:
79#       Result is cached.
80#
81#       If function CFNotificationCenterGetDarwinNotifyCenter is in the CoreFoundation framework, defines the following variables:
82#               HAVE_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER
83#
84#------------------------------------------------------------------------
85AC_DEFUN(MP_CHECK_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER, [
86        FRAMEWORK_LIBS="-framework CoreFoundation"
87
88        AC_MSG_CHECKING([for CFNotificationCenterGetDarwinNotifyCenter])
89
90        AC_CACHE_VAL(mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter, [
91                ac_save_LIBS="$LIBS"
92                LIBS="$FRAMEWORK_LIBS $LIBS"
93               
94                AC_LINK_IFELSE([
95                        AC_LANG_PROGRAM([
96                                        #include <CoreFoundation/CoreFoundation.h>
97                                ], [
98                                        CFNotificationCenterRef ref = CFNotificationCenterGetDarwinNotifyCenter();
99                        ])
100                        ], [
101                                mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter="yes"
102                        ], [
103                                mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter="no"
104                        ]
105                )
106
107                LIBS="$ac_save_LIBS"
108        ])
109
110        AC_MSG_RESULT(${mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter})
111
112        if test x"${mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter}" = "xyes"; then
113                AC_DEFINE([HAVE_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER], [], [Define if function CFNotificationCenterGetDarwinNotifyCenter in CoreFoundation framework])
114        fi
115
116        AC_SUBST(HAVE_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER)
117])
118
119
120#------------------------------------------------------------------------
121# MP_CHECK_FRAMEWORK_SYSTEMCONFIGURATION --
122#
123#       Check if SystemConfiguration framework is available, define HAVE_FRAMEWORK_SYSTEMCONFIGURATION if so.
124#
125# Arguments:
126#       None.
127#
128# Requires:
129#       None.
130#
131# Depends:
132#               AC_LANG_PROGRAM
133#
134# Results:
135#       Result is cached.
136#
137#       If SystemConfiguration framework is available, defines the following variables:
138#               HAVE_FRAMEWORK_SYSTEMCONFIGURATION
139#
140#------------------------------------------------------------------------
141AC_DEFUN(MP_CHECK_FRAMEWORK_SYSTEMCONFIGURATION, [
142        FRAMEWORK_LIBS="-framework SystemConfiguration"
143
144        AC_MSG_CHECKING([for SystemConfiguration framework])
145
146        AC_CACHE_VAL(mp_cv_have_framework_systemconfiguration, [
147                ac_save_LIBS="$LIBS"
148                LIBS="$FRAMEWORK_LIBS $LIBS"
149               
150                AC_LINK_IFELSE([
151                        AC_LANG_PROGRAM([
152                                        #include <SystemConfiguration/SystemConfiguration.h>
153                                ], [
154                                        int err = SCError();
155                                        SCDynamicStoreRef dsRef = SCDynamicStoreCreate(NULL, NULL, NULL, NULL);
156                        ])
157                        ], [
158                                mp_cv_have_framework_systemconfiguration="yes"
159                        ], [
160                                mp_cv_have_framework_systemconfiguration="no"
161                        ]
162                )
163
164                LIBS="$ac_save_LIBS"
165        ])
166
167        AC_MSG_RESULT(${mp_cv_have_framework_systemconfiguration})
168
169        if test x"${mp_cv_have_framework_systemconfiguration}" = "xyes"; then
170                AC_DEFINE([HAVE_FRAMEWORK_SYSTEMCONFIGURATION], [], [Define if SystemConfiguration framework is available])
171        fi
172
173        AC_SUBST(HAVE_FRAMEWORK_SYSTEMCONFIGURATION)
174])
175
176
177#------------------------------------------------------------------------
178# MP_CHECK_FRAMEWORK_IOKIT --
179#
180#       Check if IOKit framework is available, define HAVE_FRAMEWORK_IOKIT if so.
181#
182# Arguments:
183#       None.
184#
185# Requires:
186#       None.
187#
188# Depends:
189#               AC_LANG_PROGRAM
190#
191# Results:
192#       Result is cached.
193#
194#       If IOKit framework is available, defines the following variables:
195#               HAVE_FRAMEWORK_IOKIT
196#
197#------------------------------------------------------------------------
198AC_DEFUN(MP_CHECK_FRAMEWORK_IOKIT, [
199        FRAMEWORK_LIBS="-framework IOKit"
200
201        AC_MSG_CHECKING([for IOKit framework])
202
203        AC_CACHE_VAL(mp_cv_have_framework_iokit, [
204                ac_save_LIBS="$LIBS"
205                LIBS="$FRAMEWORK_LIBS $LIBS"
206               
207                AC_LINK_IFELSE([
208                        AC_LANG_PROGRAM([
209                                        #include <IOKit/IOKitLib.h>
210                                ], [
211                                        IOCreateReceivePort(0, NULL);
212                                        IORegisterForSystemPower(0, NULL, NULL, NULL);
213                        ])
214                        ], [
215                                mp_cv_have_framework_iokit="yes"
216                        ], [
217                                mp_cv_have_framework_iokit="no"
218                        ]
219                )
220
221                LIBS="$ac_save_LIBS"
222        ])
223
224        AC_MSG_RESULT(${mp_cv_have_framework_iokit})
225
226        if test x"${mp_cv_have_framework_iokit}" = "xyes"; then
227                AC_DEFINE([HAVE_FRAMEWORK_IOKIT], [], [Define if IOKit framework is available])
228        fi
229
230        AC_SUBST(HAVE_FRAMEWORK_IOKIT)
231])
232
233
234dnl This macro checks if the user specified a ports tree
235dnl explicitly. If not, search for it
236
237# MP_PATH_PORTSDIR(DEFAULT_PORTSDIR)
238#---------------------------------------
239 AC_DEFUN([MP_PATH_PORTSDIR],[
240        dnl For ease of reading, run after gcc has been found/configured
241        AC_REQUIRE([AC_PROG_CC])
242
243        AC_ARG_WITH(ports-dir, [AS_HELP_STRING([--with-ports-dir=DIR],[Specify alternate ports directory])], [ portsdir="$withval" ] )
244
245
246        AC_MSG_CHECKING([for ports tree])
247        if test "x$portsdir" != "x" ; then
248          if test -d "$portsdir" -a -e "$portsdir/PortIndex" ; then
249                :
250          else
251                AC_MSG_ERROR([$portsdir not a valid ports tree])
252          fi
253        else
254                dnl If the user didn't give a path, look for default
255                if test "x$1" != "x" ; then
256                  if test -d "$1" -a -e "$1/PortIndex" ; then
257                        portsdir=$1
258                  fi
259                fi
260        fi
261
262        if test "x$portsdir" != "x" ; then
263                AC_MSG_RESULT($portsdir)
264                PORTSDIR="$portsdir"
265                AC_SUBST(PORTSDIR)
266        else
267                AC_MSG_WARN([No ports tree found])
268        fi
269
270         ])
271
272
273# MP_PATH_MPCONFIGDIR
274#---------------------------------------
275AC_DEFUN([MP_PATH_MPCONFIGDIR],[
276        dnl if the user actually specified --prefix, shift
277        dnl mpconfigdir to $prefix/etc/macports
278        dnl     AC_REQUIRE([MP_PATH_PORTSDIR])
279       
280        AC_MSG_CHECKING([for MacPorts config directory])
281
282        mpconfigdir='${sysconfdir}/macports'
283
284        AC_MSG_RESULT([$mpconfigdir])
285        MPCONFIGDIR="$mpconfigdir"
286        AC_SUBST(MPCONFIGDIR)
287
288        ])
289
290# MP_CHECK_OLDLAYOUT
291#---------------------------------------
292AC_DEFUN([MP_CHECK_OLDLAYOUT],[
293        dnl Bail if there is an existing install of DP/MP older than 1.5
294
295        AC_MSG_CHECKING([that any existing MacPorts install can be upgraded])
296
297        eval dpversionfile="${sysconfdir}/ports/dp_version"
298        if test -f $dpversionfile; then
299                AC_MSG_ERROR([Existing MacPorts or DarwinPorts install is too old to be upgraded. Install MacPorts 1.7.1 first.])
300        else
301                AC_MSG_RESULT([yes])
302        fi
303
304        ])
305
306# MP_CHECK_NOROOTPRIVILEGES
307#-------------------------------------------------
308AC_DEFUN([MP_CHECK_NOROOTPRIVILEGES],[
309        dnl if with user specifies --with-no-root-privileges,
310        dnl use current user and group.
311        dnl use ~/Library/Tcl as Tcl package directory
312                AC_REQUIRE([MP_PATH_MPCONFIGDIR])
313
314        AC_ARG_WITH(no-root-privileges, [AS_HELP_STRING([--with-no-root-privileges],[Specify that MacPorts should be installed in your home directory])], [ROOTPRIVS=$withval] )
315
316        if test "${ROOTPRIVS+set}" = set; then
317
318                # Set install-user to current user
319                AC_MSG_CHECKING([for install user])
320                DSTUSR=`id -un`
321                AC_MSG_RESULT([$DSTUSR])
322                AC_SUBST(DSTUSR)
323               
324                # Set install-group to current user
325                AC_MSG_CHECKING([for install group])
326                DSTGRP=`id -gn`
327                AC_MSG_RESULT([$DSTGRP])
328                AC_SUBST(DSTGRP)
329
330                # Set Tcl package directory to ~/Library/Tcl
331            AC_MSG_CHECKING(for Tcl package directory)
332                ac_cv_c_tclpkgd="~$DSTUSR/Library/Tcl"
333            # Convert to a native path and substitute into the output files.
334            PACKAGE_DIR_NATIVE=`${CYGPATH} ${ac_cv_c_tclpkgd}`
335            TCL_PACKAGE_DIR=${PACKAGE_DIR_NATIVE}
336            AC_SUBST(TCL_PACKAGE_DIR)
337                if test x"${ac_cv_c_tclpkgd}" = x ; then
338                        AC_MSG_ERROR(Tcl package directory not found.  Please specify its location with --with-tclpackage)
339            else
340                        AC_MSG_RESULT(${ac_cv_c_tclpkgd})
341            fi
342        fi
343
344])
345
346# MP_CHECK_RUNUSER
347#-------------------------------------------------
348AC_DEFUN([MP_CHECK_RUNUSER],[
349        dnl if with user specifies --with-macports-user,
350        dnl use it. otherwise default to platform defaults
351       AC_REQUIRE([MP_PATH_MPCONFIGDIR])
352
353        AC_ARG_WITH(macports-user, [AS_HELP_STRING([--with-macports-user=USER],[Specify user to drop privileges to, if possible, during compiles etc.])], [ RUNUSR=$withval ] )
354       
355        AC_MSG_CHECKING([for macports user])
356        if test "x$RUNUSR" = "x" ; then
357           RUNUSR=nobody
358        fi
359
360        AC_MSG_RESULT([$RUNUSR])
361        AC_SUBST(RUNUSR)
362])
363
364
365# MP_SHARED_DIRECTORY
366#-------------------------------------------------
367AC_DEFUN([MP_SHARED_DIRECTORY],[
368        dnl if with user specifies --with-shared-directory,
369        dnl use 0775 permissions for ${prefix} directories
370        AC_REQUIRE([MP_PATH_MPCONFIGDIR])
371
372        AC_ARG_WITH(shared-directory, [AS_HELP_STRING([--with-shared-directory],[Use 0775 permissions for installed directories])], [ SHAREDIR=$withval ] )
373
374        if test "${SHAREDIR+set}" = set; then   
375                AC_MSG_CHECKING([whether to share the install directory with all members of the install group])
376            DSTMODE=0775
377
378                AC_MSG_RESULT([$DSTMODE])
379                AC_SUBST(DSTMODE)
380        fi
381])
382
383# MP_CHECK_INSTALLUSER
384#-------------------------------------------------
385AC_DEFUN([MP_CHECK_INSTALLUSER],[
386        dnl if with user specifies --with-install-user,
387        dnl use it. otherwise default to platform defaults
388        AC_REQUIRE([MP_PATH_MPCONFIGDIR])
389
390        AC_ARG_WITH(install-user, [AS_HELP_STRING([--with-install-user=USER],[Specify user ownership of installed files])], [ DSTUSR=$withval ] )
391       
392        AC_MSG_CHECKING([for install user])
393        if test "x$DSTUSR" = "x" ; then
394           DSTUSR=root
395        fi
396
397        AC_MSG_RESULT([$DSTUSR])
398        AC_SUBST(DSTUSR)
399])
400
401# MP_CHECK_INSTALLGROUP
402#-------------------------------------------------
403AC_DEFUN([MP_CHECK_INSTALLGROUP],[
404        dnl if with user specifies --with-install-group,
405        dnl use it. otherwise default to platform defaults
406        AC_REQUIRE([MP_CHECK_INSTALLUSER])
407
408        AC_ARG_WITH(install-group, [AS_HELP_STRING([--with-install-group=GROUP],[Specify group ownership of installed files])], [ DSTGRP=$withval ] )
409
410        AC_MSG_CHECKING([for install group])
411        if test "x$DSTGRP" = "x" ; then
412           
413           case $host_os in
414           darwin*)
415                DSTGRP="admin"
416                ;;
417           freebsd*)
418                DSTGRP="wheel"
419                ;;
420           linux*)
421                DSTGRP="root"
422                ;;
423           *)
424                DSTGRP="wheel"
425                ;;
426           esac
427        fi
428
429        AC_MSG_RESULT([$DSTGRP])
430        AC_SUBST(DSTGRP)
431])
432
433# MP_DIRECTORY_MODE
434#-------------------------------------------------
435AC_DEFUN([MP_DIRECTORY_MODE],[
436        dnl if with user specifies --with-directory-mode,
437        dnl use the specified permissions for ${prefix} directories
438        dnl otherwise use 0755
439        AC_REQUIRE([MP_PATH_MPCONFIGDIR])
440
441        AC_ARG_WITH(directory-mode, [AS_HELP_STRING([--with-directory-mode=MODE],[Specify directory mode of installed directories])], [ DSTMODE=$withval ] )
442       
443        AC_MSG_CHECKING([what permissions to use for installation directories])
444        if test "x$DSTMODE" = "x" ; then
445           DSTMODE=0755
446        fi
447
448        AC_MSG_RESULT([$DSTMODE])
449        AC_SUBST(DSTMODE)
450])
451
452# MP_PATH_APPLICATIONS
453#---------------------------------------
454AC_DEFUN([MP_PATH_APPLICATIONS],[
455        AC_REQUIRE([MP_CHECK_INSTALLUSER])
456
457    AC_ARG_WITH(applications-dir,[AS_HELP_STRING([--with-applications-dir],[Applications installation directory.])], MPAPPLICATIONSDIR=${withval})
458
459    oldprefix=$prefix
460    if test "x$prefix" = "xNONE" ; then
461        prefix=$ac_default_prefix
462    fi
463    AC_MSG_CHECKING([for Applications installation directory])
464
465        if test "x$MPAPPLICATIONSDIR" = "x" ; then
466            if test "$DSTUSR" = "root" ; then
467                MPAPPLICATIONSDIR="/Applications/MacPorts"
468            else
469                MPAPPLICATIONSDIR="$(eval echo ~$DSTUSR)/Applications/MacPorts"
470            fi
471        fi
472
473        AC_MSG_RESULT([$MPAPPLICATIONSDIR])
474    AC_SUBST(MPAPPLICATIONSDIR)
475    prefix=$oldprefix
476])
477
478# MP_PATH_FRAMEWORKS
479#---------------------------------------
480AC_DEFUN([MP_PATH_FRAMEWORKS],[
481        AC_REQUIRE([MP_CHECK_INSTALLUSER])
482
483    AC_ARG_WITH(frameworks-dir,[AS_HELP_STRING([--with-frameworks-dir],[Frameworks installation directory.])], MPFRAMEWORKSDIR=${withval})
484
485    oldprefix=$prefix
486    if test "x$prefix" = "xNONE" ; then
487        prefix=$ac_default_prefix
488    fi
489    AC_MSG_CHECKING([for Frameworks installation directory])
490
491        if test "x$MPFRAMEWORKSDIR" = "x" ; then
492                MPFRAMEWORKSDIR="${prefix}/Library/Frameworks"
493        fi
494
495        AC_MSG_RESULT([$MPFRAMEWORKSDIR])
496    AC_SUBST(MPFRAMEWORKSDIR)
497    prefix=$oldprefix
498])
499
500
501# MP_UNIVERSAL_OPTIONS
502#---------------------------------------
503AC_DEFUN([MP_UNIVERSAL_OPTIONS],[
504  AC_ARG_WITH(universal-archs,[AS_HELP_STRING([--with-universal-archs="CPU"],[Universal CPU architectures (space separated)])], UNIVERSAL_ARCHS=${withval})
505
506  if test "x$UNIVERSAL_ARCHS" = "x"; then
507    case "$MACOSX_VERSION" in
508      10.[[0-5]]*)
509        UNIVERSAL_ARCHS="i386 ppc"
510        ;;
511      *)
512        UNIVERSAL_ARCHS="x86_64 i386"
513        ;;
514    esac
515  fi
516
517  AC_MSG_CHECKING([for Universal CPU architectures])
518  AC_MSG_RESULT([$UNIVERSAL_ARCHS])
519  AC_SUBST(UNIVERSAL_ARCHS)
520])
521
522# MP_LIB_MD5
523#---------------------------------------
524# Check for an md5 implementation
525AC_DEFUN([MP_LIB_MD5],[
526
527        # Check for libmd, which is prefered
528        AC_CHECK_LIB([md], [MD5Update],[
529                AC_CHECK_HEADERS([md5.h], ,[
530                        case $host_os in
531                                darwin*)       
532                                        AC_MSG_NOTICE([Please install the BSD SDK package from the Xcode Developer Tools CD.])
533                                        ;;
534                                *)     
535                                        AC_MSG_NOTICE([Please install the libmd developer headers for your platform.])
536                                        ;;
537                        esac
538                        AC_MSG_ERROR([libmd was found, but md5.h is missing.])
539                ])
540                AC_DEFINE([HAVE_LIBMD], ,[Define if you have the `md' library (-lmd).])
541                MD5_LIBS="-lmd"]
542        )
543        if test "x$MD5_LIBS" = "x"; then
544                AC_MSG_ERROR([Neither CommonCrypto nor libmd were found. A working md5 implementation is required.])
545        fi
546        AC_SUBST([MD5_LIBS])
547])
548
549# MP_PROG_DAEMONDO
550#---------------------------------------
551AC_DEFUN([MP_PROG_DAEMONDO],[
552        AC_REQUIRE([MP_CHECK_FRAMEWORK_COREFOUNDATION])
553        AC_REQUIRE([MP_CHECK_FRAMEWORK_SYSTEMCONFIGURATION])
554        AC_REQUIRE([MP_CHECK_FRAMEWORK_IOKIT])
555        AC_REQUIRE([MP_CHECK_FUNCTION_CFNOTIFICATIONCENTERGETDARWINNOTIFYCENTER])
556       
557    AC_MSG_CHECKING(for whether we will build daemondo)
558    result=no
559        case $host_os in
560        darwin*)
561                if test "x$mp_cv_have_framework_corefoundation" == "xyes" &&
562                   test "x$mp_cv_have_framework_systemconfiguration" == "xyes" &&
563                   test "x$mp_cv_have_framework_iokit" == "xyes" &&
564                   test "x$mp_cv_have_function_cfnotificationcentergetdarwinnotifycenter" == "xyes"; then
565                        result=yes
566                        EXTRA_PROGS="$EXTRA_PROGS daemondo"
567                        AC_CONFIG_FILES([src/programs/daemondo/Makefile])
568                fi
569                ;;
570        *)
571        esac
572        AC_MSG_RESULT(${result})
573])
574
575#------------------------------------------------------------------------
576# MP_TCL_PACKAGE_DIR --
577#
578#       Locate the correct directory for Tcl package installation
579#
580# Arguments:
581#       None.
582#
583# Requires:
584#       TCLVERSION must be set
585#       CYGPATH must be set
586#       TCLSH must be set
587#
588# Results:
589#
590#       Adds a --with-tclpackage switch to configure.
591#       Result is cached.
592#
593#       Substs the following vars:
594#               TCL_PACKAGE_DIR
595#------------------------------------------------------------------------
596
597AC_DEFUN(MP_TCL_PACKAGE_DIR, [
598        AC_REQUIRE([MP_CHECK_INSTALLUSER])
599
600    AC_MSG_CHECKING(for Tcl package directory)
601
602    AC_ARG_WITH(tclpackage, [  --with-tclpackage       Tcl package installation directory.], with_tclpackagedir=${withval})
603
604    if test x"${with_tclpackagedir}" != x ; then
605        ac_cv_c_tclpkgd=${with_tclpackagedir}
606    else
607        AC_CACHE_VAL(ac_cv_c_tclpkgd, [
608            # Use the value from --with-tclpackage, if it was given
609
610            if test x"${with_tclpackagedir}" != x ; then
611                echo "tclpackagedir"
612                ac_cv_c_tclpkgd=${with_tclpackagedir}
613            else
614                # On darwin we can do some intelligent guessing
615                case $host_os in
616                    darwin*)
617                        tcl_autopath=`echo 'puts -nonewline \$auto_path' | $TCLSH`
618                        for path in $tcl_autopath; do
619                        if test "$DSTUSR" = "root" ; then
620                            if test "$path" = "/Library/Tcl"; then
621                                ac_cv_c_tclpkgd="$path"
622                                break
623                            fi
624                            if test "$path" = "/System/Library/Tcl"; then
625                                if test -d "$path"; then
626                                    ac_cv_c_tclpkgd="$path"
627                                    break
628                                fi
629                            fi
630                        elif test "$path" = "~/Library/Tcl"; then
631                            ac_cv_c_tclpkgd="~$DSTUSR/Library/Tcl"
632                            break
633                        fi
634                        done
635                    ;;
636                esac
637                if test x"${ac_cv_c_tclpkgd}" = x ; then
638                    # Fudge a path from the first entry in the auto_path
639                    tcl_pkgpath=`echo 'puts -nonewline [[lindex \$auto_path 0]]' | $TCLSH`
640                    if test -d "$tcl_pkgpath"; then
641                        ac_cv_c_tclpkgd="$tcl_pkgpath"
642                    fi
643                    # If the first entry does not exist, do nothing
644                fi
645            fi
646        ])
647    fi
648
649    if test x"${ac_cv_c_tclpkgd}" = x ; then
650        AC_MSG_ERROR(Tcl package directory not found.  Please specify its location with --with-tclpackage)
651    else
652        AC_MSG_RESULT(${ac_cv_c_tclpkgd})
653    fi
654
655    # Convert to a native path and substitute into the output files.
656
657    PACKAGE_DIR_NATIVE=`${CYGPATH} ${ac_cv_c_tclpkgd}`
658
659    TCL_PACKAGE_DIR=${PACKAGE_DIR_NATIVE}
660
661    AC_SUBST(TCL_PACKAGE_DIR)
662])
663
664# MP_PROG_TCLSH
665#---------------------------------------
666AC_DEFUN([MP_PROG_TCLSH],[
667
668
669        case $host_os in
670                freebsd*)
671                        # FreeBSD installs a dummy tclsh (annoying)
672                        # Look for a real versioned tclsh with threads first
673                        # Look for a real versioned tclsh without threads second
674                        AC_PATH_PROG([TCLSH], [tclsh${TCL_VERSION}-threads tclsh${TCL_VERSION} tclsh])
675                        ;;
676                *)
677                        # Otherwise, look for a non-versioned tclsh
678                        AC_PATH_PROG([TCLSH], [tclsh tclsh${TCL_VERSION}])
679                        ;;
680        esac
681        if test "x$TCLSH" = "x" ; then
682                AC_MSG_ERROR([Could not find tclsh])
683        fi
684
685        AC_SUBST(TCLSH)
686])
687
688# MP_TCL_PACKAGE
689#       Determine if a Tcl package is present.
690#
691# Arguments:
692#       Package name (may include the version)
693#
694# Syntax:
695#   MP_TCL_PACKAGE (package, [action-if-found], [action-if-not-found])
696#
697# Requires:
698#       TCLSH must be set
699#
700# Results:
701#       Execute action-if-found or action-if-not-found
702#---------------------------------------
703AC_DEFUN([MP_TCL_PACKAGE],[
704        AC_MSG_CHECKING([for Tcl $1 package])
705        package_present=`echo 'if {[[catch {package require $1}]]} {puts -nonewline 0} else {puts -nonewline 1}' | $TCLSH`
706        AS_IF([test "$package_present" = "1"], [$2], [$3])[]
707])
708
709# MP_TCL_THREAD_SUPPORT
710#       Determine if thread support is available in tclsh.
711#
712# Arguments:
713#       None.
714#
715# Requires:
716#       TCLSH must be set
717#
718# Results:
719#   Fails if thread support isn't available.
720#---------------------------------------
721AC_DEFUN([MP_TCL_THREAD_SUPPORT],[
722        AC_MSG_CHECKING([whether tclsh was compiled with threads])
723        tcl_threadenabled=`echo 'puts -nonewline [[info exists tcl_platform(threaded)]]' | $TCLSH`
724        if test "$tcl_threadenabled" = "1" ; then
725                AC_MSG_RESULT([yes])
726        else
727                AC_MSG_RESULT([no])
728                AC_MSG_ERROR([tcl wasn't compiled with threads enabled])
729        fi
730])
731
732# MP_LIBCURL_FLAGS
733#       Sets the flags to compile with libcurl.
734#
735# Arguments:
736#       None.
737#
738# Requires:
739#   curl-config or user parameters to define the flags.
740#
741# Results:
742#   defines some help strings.
743#   sets CFLAGS_LIBCURL and LDFLAGS_LIBCURL
744#---------------------------------------
745AC_DEFUN([MP_LIBCURL_FLAGS],[
746        AC_ARG_WITH(curlprefix,
747                   [  --with-curlprefix       base directory for the cURL install '/usr', '/usr/local',...],
748                   [  curlprefix=$withval ])
749
750        if test "x$curlprefix" = "x"; then
751                AC_PATH_PROG([CURL_CONFIG], [curl-config])
752        else
753                AC_PATH_PROG([CURL_CONFIG], [curl-config], , [$curlprefix/bin])
754        fi
755
756        if test "x$CURL_CONFIG" = "x"; then
757                AC_MSG_ERROR([cannot find curl-config. Is libcurl installed?])
758        fi
759
760        CFLAGS_LIBCURL=$($CURL_CONFIG --cflags)
761        if test "x$curlprefix" = "x"; then
762                # System curl-config emits absurd output for --libs
763                # See rdar://7244457
764                LDFLAGS_LIBCURL="-lcurl"
765        else
766                # Due to a bug in dist, --arch flags are improperly supplied by curl-config.
767                # Get rid of them.
768                LDFLAGS_LIBCURL=$($CURL_CONFIG --libs | [sed 's/-arch [A-Za-z0-9_]* //g'])
769        fi
770
771        AC_SUBST(CFLAGS_LIBCURL)
772        AC_SUBST(LDFLAGS_LIBCURL)
773])
774
775# MP_SQLITE3_FLAGS
776#       Sets the flags to compile with libsqlite3 and tclsqlite3.
777#
778# Arguments:
779#       None.
780#
781# Requires:
782#   pkgconfig, libsqlite3 in /usr/lib, or user parameters to define the flags.
783#
784# Results:
785#   defines some help strings.
786#   sets CFLAGS_SQLITE3 and LDFLAGS_SQLITE3
787#---------------------------------------
788AC_DEFUN([MP_SQLITE3_FLAGS],[
789    # first sqlite3 itself
790        AC_ARG_WITH(sqlite3prefix,
791                   [  --with-sqlite3prefix       base directory for the sqlite3 install '/usr', '/usr/local',...],
792                   [  sqlite3prefix=$withval ])
793
794        if test "x$sqlite3prefix" = "x"; then
795                AC_PATH_PROG([PKG_CONFIG], [pkg-config])
796                if test "x$PKG_CONFIG" = "x" || ! $PKG_CONFIG --exists sqlite3; then
797                    # assume it's somewhere like /usr that needs no extra flags
798                    AC_CHECK_HEADER(sqlite3.h, [], [AC_MSG_ERROR([cannot find sqlite3 header])])
799            CFLAGS_SQLITE3=""
800                    LDFLAGS_SQLITE3="-lsqlite3"
801        else
802            CFLAGS_SQLITE3=$($PKG_CONFIG --cflags sqlite3)
803            LDFLAGS_SQLITE3=$($PKG_CONFIG --libs sqlite3)
804            # for tclsqlite below
805            mp_sqlite3_dir=$($PKG_CONFIG --variable=prefix sqlite3)
806            if test "x$mp_sqlite3_dir" != "x"; then
807                mp_sqlite3_dir=${mp_sqlite3_dir}/lib/sqlite3
808            fi
809        fi
810        else
811            CFLAGS_SQLITE3="-I${sqlite3prefix}/include"
812                LDFLAGS_SQLITE3="-L${sqlite3prefix}/lib -lsqlite3"
813        fi
814
815    # check if we have sqlite3ext.h, using the appropriate cppflags
816    CPPFLAGS_OLD="${CPPFLAGS}"
817    CPPFLAGS="${CPPFLAGS} ${CFLAGS_SQLITE3}"
818    AC_CHECK_HEADERS(sqlite3ext.h)
819    CPPFLAGS="${CPPFLAGS_OLD}"
820
821        AC_SUBST(CFLAGS_SQLITE3)
822        AC_SUBST(LDFLAGS_SQLITE3)
823
824        # now the sqlite Tcl bindings
825        AC_ARG_WITH(tcl-sqlite3,
826                AS_HELP_STRING([--with-tcl-sqlite3=DIR],
827                        [directory for Tcl sqlite3 (default /usr/lib/sqlite3)]),
828                [mp_sqlite3_dir=$withval])
829
830    if test "x$mp_sqlite3_dir" = "x"; then
831        case $host_os in
832            darwin*)
833                mp_sqlite3_dir="/usr/lib/sqlite3"
834                ;;
835            freebsd*)
836                mp_sqlite3_dir="/usr/local/lib/sqlite"
837                ;;
838            *)
839                mp_sqlite3_dir="/usr/share/tcl${TCL_VERSION}/sqlite3"
840                ;;
841        esac
842    fi
843
844        AC_CACHE_CHECK([for Tcl sqlite3 location], [mp_cv_sqlite3_dir],
845                [mp_cv_sqlite3_dir=
846                test -r "${mp_sqlite3_dir}/pkgIndex.tcl" && mp_cv_sqlite3_dir=$mp_sqlite3_dir
847                ])
848
849        SQLITE3_TCL_DIR=$mp_cv_sqlite3_dir
850        AC_SUBST(SQLITE3_TCL_DIR)
851])
852
853dnl This macro tests if the compiler supports GCC's
854dnl __attribute__ syntax for unused variables/parameters
855AC_DEFUN([MP_COMPILER_ATTRIBUTE_UNUSED], [
856        AC_MSG_CHECKING([how to mark unused variables])
857        AC_COMPILE_IFELSE(
858                [AC_LANG_SOURCE([[int a __attribute__ ((unused));]])],
859                [AC_DEFINE(UNUSED, [__attribute__((unused))], [Attribute to mark unused variables])],
860                [AC_DEFINE(UNUSED, [])])
861
862        AC_MSG_RESULT([])
863       
864])
865
866dnl This macro ensures MP installation prefix bin/sbin paths are NOT in PATH
867dnl for configure to prevent potential problems when base/ code is updated
868dnl and ports are installed that would match needed items.
869AC_DEFUN([MP_PATH_SCAN],[
870        oldprefix=$prefix
871        if test "x$prefix" = "xNONE" ; then
872                prefix=$ac_default_prefix
873        fi
874        oldPATH=$PATH
875        newPATH=
876        as_save_IFS=$IFS; IFS=$PATH_SEPARATOR
877        for as_dir in $oldPATH
878        do
879                IFS=$as_save_IFS
880                if test "x$as_dir" != "x$prefix/bin" &&
881                        test "x$as_dir" != "x$prefix/sbin"; then
882                        if test -z "$newPATH"; then
883                                newPATH=$as_dir
884                        else
885                                newPATH=$newPATH$PATH_SEPARATOR$as_dir
886                        fi
887                fi
888        done
889        PATH=$newPATH; export PATH
890        AC_SUBST(PATH_CLEANED,$newPATH)
891        prefix=$oldprefix
892])
893
894dnl This macro tests for sed support of -E (BSD) or -r (GNU)
895AC_DEFUN([MP_SED_EXTENDED_REGEXP],[
896        AC_PATH_PROG(SED, [sed])
897
898        if test "x$SED" = "x"; then
899                AC_MSG_ERROR([cannot find sed. Is sed installed?])
900        fi
901
902        AC_MSG_CHECKING([which sed flag to use for extended regexp])
903        [any_sed_flag=`echo foo | $SED    -e s/foo+/OK/ 2>&1 | grep OK`]
904        [bsd_sed_flag=`echo foo | $SED -E -e s/foo+/OK/ 2>&1 | grep OK`]
905        [gnu_sed_flag=`echo foo | $SED -r -e s/foo+/OK/ 2>&1 | grep OK`]
906        if test "x$any_sed_flag" = "xOK" ; then
907                AC_MSG_RESULT([none])
908                SED_EXT=
909        elif test "x$bsd_sed_flag" = "xOK" ; then
910                AC_MSG_RESULT([-E (BSD)])
911                SED_EXT=-E
912        elif test "x$gnu_sed_flag" = "xOK" ; then
913                AC_MSG_RESULT([-r (GNU)])
914                SED_EXT=-r
915        else
916                AC_MSG_RESULT([not available])
917                SED_EXT='N/A'
918        fi
919        AC_SUBST(SED_EXT)
920])
921
922dnl This macro tests for tar support of -q (BSD) or not (GNU)
923AC_DEFUN([MP_TAR_FAST_READ],[
924        AC_PATH_PROG(TAR, [tar])
925       
926        AC_MSG_CHECKING([whether tar supports -q])
927        if $TAR -t -q -f - </dev/null 2>/dev/null ; then
928                AC_MSG_RESULT([yes (bsdtar)])
929                TAR_Q='q'
930        else
931                AC_MSG_RESULT([no (gnutar)])
932                TAR_Q=
933        fi
934        AC_SUBST(TAR_Q)
935])
936
937dnl This macro tests for tar support of --no-same-owner
938AC_DEFUN([MP_TAR_NO_SAME_OWNER],[
939        AC_PATH_PROG(TAR, [tar])
940        AC_PATH_PROG(GNUTAR, [gnutar])
941       
942        AC_MSG_CHECKING([for which tar variant to use])
943        AS_IF([test -n "$GNUTAR"], [TAR_CMD=$GNUTAR], [TAR_CMD=$TAR])
944        AC_MSG_RESULT([$TAR_CMD])
945        AC_SUBST(TAR_CMD)
946
947        AC_MSG_CHECKING([for $TAR_CMD --no-same-owner support])
948        [no_same_owner_support=`$TAR_CMD --help 2>&1 | grep no-same-owner`]
949        if test -z "$no_same_owner_support" ; then
950                AC_MSG_RESULT([no])
951        else
952                AC_MSG_RESULT([yes])
953                TAR_CMD="$TAR_CMD --no-same-owner"
954        fi
955])
956
957dnl This macro tests for GNU patch
958AC_DEFUN([MP_PATCH_GNU_VERSION],[
959        AC_PATH_PROG(PATCH, [patch])
960        AC_PATH_PROG(GNUPATCH, [gpatch])
961       
962        AC_MSG_CHECKING([for GNU (FSF) patch])
963        AS_IF([test -n "$GNUPATCH"], [PATCH_CMD=$GNUPATCH], [PATCH_CMD=$PATCH])
964        [fsf_version=`$PATCH_CMD --version 2>&1 | grep "Free Software Foundation"`]
965        if test -z "$fsf_version" ; then
966                AC_MSG_RESULT([none])
967        else
968                AC_MSG_RESULT([$PATCH_CMD])
969                GNUPATCH="$PATCH_CMD"
970        fi
971])
972
973#------------------------------------------------------------------------
974# MP_CHECK_READLINK_IS_P1003_1A --
975#
976#       Check if readlink conforms to POSIX 1003.1a standard, define
977#       READLINK_IS_NOT_P1003_1A if it doesn't.
978#
979# Arguments:
980#       None.
981#
982# Requires:
983#       None.
984#
985# Depends:
986#               AC_LANG_PROGRAM
987#
988# Results:
989#       Result is cached.
990#
991#       If readlink doesn't conform to POSIX 1003.1a, defines the following variables:
992#               READLINK_IS_NOT_P1003_1A
993#
994#------------------------------------------------------------------------
995AC_DEFUN(MP_CHECK_READLINK_IS_P1003_1A, [
996        AC_MSG_CHECKING([if readlink conforms to POSIX 1003.1a])
997
998        AC_CACHE_VAL(mp_cv_readlink_is_posix_1003_1a, [
999                AC_COMPILE_IFELSE([
1000                        AC_LANG_PROGRAM([
1001                                        #include <unistd.h>
1002                                        ssize_t readlink(const char *, char *, size_t);
1003                                ], [
1004                        ])
1005                        ], [
1006                                mp_cv_readlink_is_posix_1003_1a="yes"
1007                        ], [
1008                                mp_cv_readlink_is_posix_1003_1a="no"
1009                        ]
1010                )
1011        ])
1012
1013        AC_MSG_RESULT(${mp_cv_readlink_is_posix_1003_1a})
1014
1015        if test x"${mp_cv_readlink_is_posix_1003_1a}" = "xno"; then
1016                AC_DEFINE([READLINK_IS_NOT_P1003_1A], [], [Define to 1 if readlink does not conform with POSIX 1003.1a (where third argument is a size_t and return value is a ssize_t)])
1017        fi
1018
1019        AC_SUBST(READLINK_IS_NOT_P1003_1A)
1020])
1021
1022#------------------------------------------------------------------------
1023# MP_WERROR --
1024#
1025#       Enable -Werror
1026#
1027# Arguments:
1028#       None.
1029#
1030# Requires:
1031#       none
1032#
1033# Depends:
1034#       none
1035#
1036# Results:
1037#       Substitutes WERROR_CFLAGS variable
1038#------------------------------------------------------------------------
1039AC_DEFUN([MP_WERROR],[
1040        AC_REQUIRE([AC_PROG_CC])
1041        AC_ARG_ENABLE(werror, AS_HELP_STRING([--enable-werror],[Add -Werror to CFLAGS. Used for development.]), [enable_werror=${enableval}], [enable_werror=no])
1042        if test x"$enable_werror" != "xno"; then
1043                CFLAGS_WERROR="-Werror"
1044        else
1045                CFLAGS_WERROR=""
1046        fi
1047        AC_SUBST([CFLAGS_WERROR])
1048])
Note: See TracBrowser for help on using the repository browser.