source: trunk/base/configure.ac @ 35626

Last change on this file since 35626 was 34875, checked in by eridius@…, 12 years ago

Add support for fetch.type git (Fixes #14232)

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 12.1 KB
Line 
1dnl Process this file with autoconf to produce a configure script.
2dnl $Id: configure.ac 34875 2008-03-10 04:50:45Z eridius@macports.org $
3AC_PREREQ(2.52)
4AC_DEFUN([MACPORTS_VERSION_MACRO], [esyscmd(cat config/macports_version | tr -d '\n')])
5AC_INIT([MacPorts], [MACPORTS_VERSION_MACRO], [macports-dev@lists.macosforge.org], [macports])
6AC_CONFIG_SRCDIR([src/pextlib1.0/Pextlib.c])
7AC_CONFIG_HEADERS([src/config.h])
8AC_CANONICAL_SYSTEM
9
10# Read in the MacPorts version from the base/config/macports_vesion file
11AC_MSG_CHECKING(MacPorts version)
12MACPORTS_VERSION=MACPORTS_VERSION_MACRO
13AC_MSG_RESULT([$MACPORTS_VERSION])
14AC_SUBST(MACPORTS_VERSION)
15# Read the old, floating point format version, which we still use internally, and export it for the $macports::autoconf::macports_version variable
16MP_VERSION=$(cat config/mp_version | tr -d '\n')
17AC_SUBST(MP_VERSION)
18
19# Check user PATH for MP paths, and remove as necessary.
20MP_PATH_SCAN
21
22AC_CHECK_PROGS(SW_VERS, sw_vers)
23if test "x$SW_VERS" != "x"; then
24  AC_MSG_CHECKING(Mac OS X version)
25  MACOSX_VERSION=`$SW_VERS -productVersion | cut -f 1-3 -d.`
26  AC_MSG_RESULT([$MACOSX_VERSION])
27fi
28
29case "$MACOSX_VERSION" in
30  10.0*|10.1*|10.2*)
31    AC_WARN(This version of Mac OS X is not supported)
32    AC_WARN(Please upgrade at http://store.apple.com/)
33    ;;
34  10.1.[[0-4]]|10.2.[[0-7]]|10.3.[[0-8]]|10.4.[[0-8]])
35    AC_WARN(This version of Mac OS X is out of date)
36    AC_WARN(Please run Software Update to update it)
37    ;;
38  10.3*|10.4*|10.5*)
39    dnl Supported version
40    ;;
41  *)
42    ;;
43esac
44
45XCODEPLIST=/Developer/Applications/Xcode.app/Contents/version.plist
46if test -r "$XCODEPLIST"; then
47  AC_MSG_CHECKING(Xcode version)
48  XCODE_VERSION=`tr -d '\r\n' < $XCODEPLIST | sed -e 's/.*<key>CFBundleShortVersionString<\/key>.<string>\([[0-9.]]*\)<\/string>.*/\1/'`
49  AC_MSG_RESULT([$XCODE_VERSION])
50fi
51
52case "$XCODE_VERSION" in
53  1.[[0-1]]*|2.[[0-1]]*)
54    AC_WARN(This version of Xcode Tools is not supported)
55    AC_WARN(Please upgrade at http://connect.apple.com/)
56    ;;
57  1.[[2-4]]*|2.[[2-3]]*)
58    AC_WARN(This version of Xcode Tools is out of date)
59    AC_WARN(Please consider upgrading as some ports fail compiling)
60    ;;
61  1.5*|2.4*|3.*)
62    dnl Supported version
63    ;;
64  *)
65    ;;
66esac
67
68# Checks for programs.
69AC_PROG_CC
70AC_PROG_OBJC
71AC_PROG_INSTALL
72AC_PROG_MAKE_SET
73AC_PROG_LN_S
74AC_PATH_PROG(MTREE, [mtree], [], [$PATH:/usr/sbin])
75AC_PATH_PROG(CVS, [cvs], [])
76AC_PATH_PROG(SVN, [svn], [])
77AC_PATH_PROG(GIT, [git], [])
78AC_PATH_PROG(RSYNC, [rsync], [])
79AC_PATH_PROG(SED, [sed])
80AC_PATH_PROG(TAR, [tar])
81AC_PATH_PROG(MAKE, [make])
82AC_CHECK_PROG(HAVE_LAUNCHD, [launchd], [yes], [])
83AC_PATH_PROG(LAUNCHCTL, [launchctl], [])
84AC_PATH_PROG(XCODEBUILD, [xcodebuild], [])
85AC_PATH_PROGS(GNUTAR, [gnutar gtar], [], [$PATH:/usr/local/bin])
86AC_PATH_PROGS(GNUMAKE, [gnumake gmake], [], [$PATH:/usr/local/bin])
87AC_PATH_PROG(BZIP2, [bzip2], [])
88AC_PATH_PROG(XAR, [xar], [])
89AC_PATH_PROG(OPEN, [open], [])
90
91# Define some precious variables allowing user to override PATH for some programs
92AC_ARG_VAR(MTREE, [path to mtree command])
93AC_ARG_VAR(CVS, [path to cvs command])
94AC_ARG_VAR(SVN, [path to svn command])
95AC_ARG_VAR(RSYNC, [path to rsync command])
96AC_ARG_VAR(SED, [path to sed command])
97AC_ARG_VAR(TAR, [path to tar command])
98AC_ARG_VAR(MAKE, [path to make command])
99AC_ARG_VAR(GNUTAR, [path to gnutar command])
100AC_ARG_VAR(GNUMAKE, [path to gnumake command])
101AC_ARG_VAR(BZIP2, [path to bzip2 command])
102AC_ARG_VAR(XAR, [path to xar command])
103AC_ARG_VAR(OPEN, [path to open command])
104
105MP_SED_EXTENDED_REGEXP
106MP_TAR_NO_SAME_OWNER
107
108# Quiche eaters options.
109if test x$GCC = xyes; then
110        CFLAGS_QUICHEEATERS='-W -Wall -pedantic'
111fi
112AC_SUBST(CFLAGS_QUICHEEATERS)
113MP_WERROR
114
115MP_COMPILER_ATTRIBUTE_UNUSED
116MP_COMPILER_ATTRIBUTE_LF_PRIVATE
117
118# Foundation checks
119ACX_PTHREAD
120MP_OBJC_RUNTIME
121MP_OBJC_FOUNDATION
122
123MP_PROG_DAEMONDO
124#MP_PROG_XAR
125
126AC_SUBST(REPLACEMENT_PROGS)
127AC_SUBST(EXTRA_PROGS)
128
129# set default ports-directory
130PORTS_DIR_DEFAULT=`pwd | sed -e "s/base/ports/"`
131
132# Check for paths
133AC_PREFIX_DEFAULT(/opt/local)
134MP_PATH_PORTSDIR([$PORTS_DIR_DEFAULT])
135MP_PATH_MPCONFIGDIR
136
137# Check for install ownership
138MP_CHECK_INSTALLUSER
139MP_CHECK_INSTALLGROUP
140MP_DIRECTORY_MODE
141
142# Check for default directories
143MP_PATH_APPLICATIONS
144MP_PATH_FRAMEWORKS
145
146# Check for universal options
147MP_UNIVERSAL_OPTIONS
148
149# Check for standard header files.
150AC_HEADER_STDC
151AC_HEADER_DIRENT
152AC_HEADER_SYS_WAIT
153AC_HEADER_STAT
154AC_CHECK_HEADERS([limits.h paths.h sys/file.h crt_externs.h fcntl.h sys/fcntl.h sys/cdefs.h err.h libgen.h sys/socket.h \
155        readline/readline.h readline/history.h pwd.h sys/paths.h utime.h])
156
157INCLUDES="-I.. -I. $INCLUDES"
158
159# Checks for library functions.
160AC_FUNC_CLOSEDIR_VOID
161AC_FUNC_FORK
162AC_FUNC_STRERROR_R
163AC_CHECK_FUNCS([bzero memset dup2 regcomp strdup strerror strtol fgetln lockf flock setmode strcasecmp strncasecmp strlcpy copyfile])
164MP_CHECK_READLINK_IS_P1003_1A
165
166AC_ARG_WITH(x11-prefix, [AC_HELP_STRING([--with-x11-prefix=PREFIX], [use PREFIX as the X11 base dir (default autodetect)])], [ x11prefix="$withval" ] )
167case "$x11prefix" in
168  "")
169    # default to traditional value
170    x11prefix=/usr/X11R6
171    ;;
172  *)
173    x_includes=$x11prefix/include
174    x_libraries=$x11prefix/lib
175    ;;
176esac
177
178# Check for md5 implementation
179MP_LIB_MD5
180# Check for X11 and paraphernalia
181MP_CHECK_X11
182
183AC_MSG_CHECKING(for X11 prefix)
184X_INCLUDES_PREFIX=`echo "$x_includes" | sed "s,/include,,"`
185X_LIBRARIES_PREFIX=`echo "$x_libraries" | sed "s,/lib,,"`
186if test "x$have_x" = "xyes" -a "x$X_INCLUDES_PREFIX" = "x$X_LIBRARIES_PREFIX" -a "x$X_LIBRARIES_PREFIX" != x; then
187    x11prefix=$X_LIBRARIES_PREFIX
188fi
189AC_MSG_RESULT([$x11prefix])
190AC_SUBST(x11prefix)
191
192# Check for readline
193AC_ARG_ENABLE(readline, AC_HELP_STRING([--enable-readline], [Enable addition of readline support, if readline present.]),
194[
195        AC_CHECK_LIB([readline], [readline], [
196                                  READLINE_LIBS=-lreadline
197                                  AC_DEFINE([HAVE_LIBREADLINE], [1], [Define to 1 if you have the `readline' library (-lreadline).])
198                                  ])
199        AC_CHECK_DECLS([rl_username_completion_function,rl_filename_completion_function,rl_completion_matches,username_completion_function,filename_completion_function,completion_matches], [], [],
200        [
201        #include <stdio.h>
202        #if HAVE_READLINE_READLINE_H
203        # include <readline/readline.h>
204        #endif
205        ])
206])
207AC_SUBST(READLINE_LIBS)
208
209# Lowest non-system-reserved uid and gid (Apple claims <500)
210AC_DEFINE([MIN_USABLE_UID], [500], [Lowest non-system-reserved UID.])
211AC_DEFINE([MIN_USABLE_GID], [500], [Lowest non-system-reserved GID.])
212
213# Load tclConfig.sh
214SC_PATH_TCLCONFIG
215SC_LOAD_TCLCONFIG
216
217# Check for Tcl public headers
218dnl XXX  hardwire CYGPATH (CYGPATH must be set for SC_PUBLIC_TCL_HEADERS)
219CYGPATH=echo
220SC_PUBLIC_TCL_HEADERS
221
222# Check for tclsh binary
223MP_PROG_TCLSH
224
225# Check for Tcl package path
226MP_TCL_PACKAGE_DIR
227
228# Check if thread is enabled.
229MP_TCL_THREAD_SUPPORT
230
231## libcurl
232MP_LIBCURL_FLAGS
233
234# Do we have curl_easy_strerror?
235AH_TEMPLATE([HAVE_CURL_EASY_STRERROR],
236               [Define to 1 if you have the curl_easy_strerror function.])
237AC_CHECK_LIB([curl], [curl_easy_strerror],
238        [AC_DEFINE([HAVE_CURL_EASY_STRERROR])],[],
239        [$LDFLAGS_LIBCURL])
240
241# Determine if we need to install some bundled packages
242OUR_INCLUDED_PACKAGES=
243
244## Thread package.
245AC_ARG_WITH(
246                included-tclthread,
247                AS_HELP_STRING([--with-included-tclthread],
248                        [install included Thread package.]),
249                [with_included_tclthread=$withval],
250                [with_included_tclthread="unspecified"])
251
252# Check if thread package is already installed.
253if test "x$with_included_tclthread" = "xunspecified" ; then
254        MP_TCL_PACKAGE(
255                [Thread],
256                [AC_MSG_RESULT([yes]); with_included_tclthread=no],
257                [AC_MSG_RESULT([no]); with_included_tclthread=yes])
258fi
259
260# If thread package isn't installed, configure and install thread package.
261if test "$with_included_tclthread" = "yes"; then
262        OUR_INCLUDED_PACKAGES="$OUR_INCLUDED_PACKAGES thread2.6"
263        AC_CONFIG_SUBDIRS([src/thread2.6])
264        # Extract thread package
265        (cd src/; gzip -d < thread2.6.tar.gz | tar xf -)
266        # Patch thread package (so thread2.6 is the vanilla distribution directory)
267        patch -p0 < src/thread2.6.diff
268fi
269
270## sqlite3 package.
271AC_ARG_WITH(
272                included-sqlite3,
273                AS_HELP_STRING([--with-included-sqlite3],
274                        [build using bundled sqlite3 package]),
275                [with_included_sqlite3=$withval],
276                [with_included_sqlite3="unspecified"])
277
278# Check if sqlite3 package is already installed.
279if test "x$with_included_sqlite3" = "xunspecified" ; then
280        AC_CHECK_LIB([sqlite3],[sqlite3_open],
281                [with_included_sqlite3=no],
282                [with_included_sqlite3=yes])
283fi
284
285AC_ARG_WITH(
286                tcl-sqlite3,
287                AS_HELP_STRING([--with-tcl-sqlite3=DIR],
288                        [directory for Tcl sqlite3 (default /usr/lib/sqlite3)]),
289                [mp_sqlite3_dir=$withval],
290                [mp_sqlite3_dir=/usr/lib/sqlite3])
291
292# If sqlite3 package isn't installed, configure and install sqlite3 package.
293if test "$with_included_sqlite3" = "yes"; then
294        OUR_INCLUDED_PACKAGES="$OUR_INCLUDED_PACKAGES sqlite-3.1.3"
295        INCLUDES="$INCLUDES -I../sqlite-3.1.3"
296        AC_CONFIG_SUBDIRS([src/sqlite-3.1.3])
297        # Extract sqlite3 package
298        (cd src/; gzip -d < sqlite-3.1.3.tar.gz | tar xf -)
299        # patch sqlite3 with desired configure options
300        patch -p0 < src/sqlite-3.1.3.diff
301        # the new tclinstaller.tcl needs to have substitution occur
302        mv src/sqlite-3.1.3/tclinstaller.tcl src/sqlite-3.1.3/tclinstaller.tcl.in
303        SQLITE3_LIBS=`pwd`"/src/sqlite-3.1.3/.libs/libsqlite3.a"
304        if test "x$prefix" = "xNONE" ; then
305                SQLITE3_DIR=$ac_default_prefix/share/macports/Tcl/sqlite3
306        else
307                SQLITE3_DIR=$prefix/share/macports/Tcl/sqlite3
308        fi
309else
310        SQLITE3_LIBS="-lsqlite3"
311
312        AC_CACHE_CHECK([for Tcl sqlite3 location], [mp_cv_sqlite3_dir],
313                [mp_cv_sqlite3_dir=
314                test -r "${mp_sqlite3_dir}/pkgIndex.tcl" && mp_cv_sqlite3_dir=$mp_sqlite3_dir
315                ])
316
317        SQLITE3_DIR=$mp_cv_sqlite3_dir
318fi
319
320AC_SUBST(SQLITE3_LIBS)
321AC_SUBST(SQLITE3_DIR)
322
323AH_TEMPLATE([TRACE_SDK], [SDK for SDK redirect in tracelib])
324AC_ARG_WITH(
325        trace-sdk,
326        AS_HELP_STRING([--with-trace-sdk=SDK],
327                [SDK for redirection in trace lib (for example MacOSX10.4u.sdk)]),
328        [test -d /Developer/SDKs/$withval && AC_DEFINE_UNQUOTED([TRACE_SDK], "${withval}")], [])
329       
330       
331# If /etc/paths.d and /etc/manpaths.d then we can install our path configuration
332# (this code is currently disabled since this mechanism implies that MacPorts paths are
333# added after the system's paths, and so MacPorts commands would not override system functions).
334AC_MSG_CHECKING(whether to install MacPorts paths into /etc/paths.d and /etc/manpaths.d)
335mpprefix=$prefix
336test "x$mpprefix" = "xNONE" && mpprefix=$ac_default_prefix
337if false && test -d /etc/paths.d -a -d /etc/manpaths.d -a "$mpprefix" = "$ac_default_prefix"; then
338        PATHCONF=pathconf
339        AC_MSG_RESULT([yes])
340else
341        AC_MSG_RESULT([no])
342fi
343
344
345# Allows building of shared libraries
346SC_ENABLE_SHARED
347
348# Pull compiler / linker values from tclConfig.sh
349CFLAGS_DEBUG=${TCL_CFLAGS_DEBUG}
350CFLAGS_OPTIMIZE=${TCL_CFLAGS_OPTIMIZE}
351LDFLAGS_DEBUG=${TCL_LDFLAGS_DEBUG}
352LDFLAGS_OPTIMIZE=${TCL_LDFLAGS_OPTIMIZE}
353SHLIB_LD=${TCL_SHLIB_LD}
354STLIB_LD=${TCL_STLIB_LD}
355SHLIB_CFLAGS=${TCL_SHLIB_CFLAGS}
356SHLIB_SUFFIX=${TCL_SHLIB_SUFFIX}
357
358AC_SUBST(INCLUDES)
359AC_SUBST(CFLAGS_DEBUG)
360AC_SUBST(CFLAGS_OPTIMIZE)
361AC_SUBST(PATHCONF)
362AC_SUBST(STLIB_LD)
363AC_SUBST(SHLIB_LD)
364AC_SUBST(SHLIB_CFLAGS)
365AC_SUBST(SHLIB_LDFLAGS)
366AC_SUBST(SHLIB_SUFFIX)
367AC_SUBST(TCL_DEFS)
368AC_SUBST(TCL_STUB_LIB_SPEC)
369AC_SUBST(TCL_CC)
370AC_SUBST(OUR_INCLUDED_PACKAGES)
371
372# misc variables that need to be expanded for substitution into tcl
373
374oldprefix=$prefix
375if test "x$prefix" = "xNONE" ; then
376   prefix=$ac_default_prefix
377fi
378
379eval "prefix_expanded=$prefix"
380AC_SUBST(prefix_expanded)
381# do this twice, since there is a nested variable of
382# ${prefix} inside of ${sysconfdir}
383eval "MPCONFIGDIR_EXPANDED=$MPCONFIGDIR"
384eval "MPCONFIGDIR_EXPANDED=$MPCONFIGDIR_EXPANDED"
385AC_SUBST(MPCONFIGDIR_EXPANDED)
386eval "localstatedir_expanded=$localstatedir"
387AC_SUBST(localstatedir_expanded)
388
389prefix=$oldprefix
390
391dnl man page settings (compressed, links, etc)
392dnl
393dnl SC_CONFIG_MANPAGES
394
395# Output
396AC_CONFIG_FILES([
397        Doxyfile
398        Makefile
399        Mk/macports.autoconf.mk
400        doc/prefix.mtree
401        doc/macosx.mtree
402        doc/macports.conf
403        portmgr/freebsd/Makefile
404        portmgr/fedora/macports.spec
405        src/Makefile
406        src/macports1.0/macports_autoconf.tcl
407        src/tclobjc1.0/Makefile
408        src/pathconf/Makefile
409        src/pathconf/paths
410        src/pathconf/manpaths
411        src/port1.0/port_autoconf.tcl
412        src/registry1.0/registry_autoconf.tcl
413        src/programs/Makefile
414        src/macports1.0/macports_fastload.tcl
415])
416
417AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.