source: trunk/base/pthread.m4 @ 26855

Last change on this file since 26855 was 26710, checked in by landonf@…, 13 years ago

Add missing macro for detecting pthread compiler/linker flags.

File size: 9.0 KB
Line 
1dnl @synopsis ACX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
2dnl
3dnl Modified from the original version:
4dnl * Removed pthread-specific CC support
5dnl * Added FreeBSD specific -pthread/-lpthread flags
6dnl Notes:
7dnl * -D_THREAD_SAFE may not be necessary on FreeBSD
8dnl   and elsewhere.
9dnl - landonf March 25th, 2005
10dnl
11dnl This macro figures out how to build C programs using POSIX threads.
12dnl It sets the PTHREAD_LIBS output variable to the threads library and
13dnl linker flags, and the PTHREAD_CFLAGS output variable to any special
14dnl C compiler flags that are needed. (The user can also force certain
15dnl compiler flags/libs to be tested by setting these environment
16dnl variables.)
17dnl
18dnl NOTE: You are assumed to not only compile your program with these
19dnl flags, but also link it with them as well. e.g. you should link
20dnl with $CC $CFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS
21dnl $LIBS
22dnl
23dnl If you are only building threads programs, you may wish to use
24dnl these variables in your default LIBS, and CFLAGS:
25dnl
26dnl        LIBS="$PTHREAD_LIBS $LIBS"
27dnl        CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
28dnl
29dnl In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute
30dnl constant has a nonstandard name, defines PTHREAD_CREATE_JOINABLE to
31dnl that name (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
32dnl
33dnl ACTION-IF-FOUND is a list of shell commands to run if a threads
34dnl library is found, and ACTION-IF-NOT-FOUND is a list of commands to
35dnl run it if it is not found. If ACTION-IF-FOUND is not specified, the
36dnl default action will define HAVE_PTHREAD.
37dnl
38dnl Please let the authors know if this macro fails on any platform, or
39dnl if you have any other suggestions or comments. This macro was based
40dnl on work by SGJ on autoconf scripts for FFTW (www.fftw.org) (with
41dnl help from M. Frigo), as well as ac_pthread and hb_pthread macros
42dnl posted by Alejandro Forero Cuervo to the autoconf macro repository.
43dnl We are also grateful for the helpful feedback of numerous users.
44dnl
45dnl @category InstalledPackages
46dnl @author Steven G. Johnson <stevenj@alum.mit.edu>
47dnl @version 2005-01-14
48dnl @license GPLWithACException
49
50AC_DEFUN([ACX_PTHREAD], [
51AC_REQUIRE([AC_CANONICAL_HOST])
52AC_LANG_SAVE
53AC_LANG_C
54acx_pthread_ok=no
55
56# We used to check for pthread.h first, but this fails if pthread.h
57# requires special compiler flags (e.g. on True64 or Sequent).
58# It gets checked for in the link test anyway.
59
60# First of all, check if the user has set any of the PTHREAD_LIBS,
61# etcetera environment variables, and if threads linking works using
62# them:
63if test x"$PTHREAD_LIBS$PTHREAD_CFLAGS" != x; then
64        save_CFLAGS="$CFLAGS"
65        CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
66        save_LIBS="$LIBS"
67        LIBS="$PTHREAD_LIBS $LIBS"
68        AC_MSG_CHECKING([for pthread_join in LIBS=$PTHREAD_LIBS with CFLAGS=$PTHREAD_CFLAGS])
69        AC_TRY_LINK_FUNC(pthread_join, acx_pthread_ok=yes)
70        AC_MSG_RESULT($acx_pthread_ok)
71        if test x"$acx_pthread_ok" = xno; then
72                PTHREAD_LIBS=""
73                PTHREAD_CFLAGS=""
74        fi
75        LIBS="$save_LIBS"
76        CFLAGS="$save_CFLAGS"
77fi
78
79# We must check for the threads library under a number of different
80# names; the ordering is very important because some systems
81# (e.g. DEC) have both -lpthread and -lpthreads, where one of the
82# libraries is broken (non-POSIX).
83
84# Create a list of thread flags to try.  Items starting with a "-" are
85# C compiler flags, and other items are library names, except for "none"
86# which indicates that we try without any flags at all, and "pthread-config"
87# which is a program returning the flags for the Pth emulation library.
88
89acx_pthread_flags="pthreads none -Kthread -kthread lthread -pthread -pthreads -mthreads pthread --thread-safe -mt pthread-config"
90
91# The ordering *is* (sometimes) important.  Some notes on the
92# individual items follow:
93
94# pthreads: AIX (must check this before -lpthread)
95# none: in case threads are in libc; should be tried before -Kthread and
96#       other compiler flags to prevent continual compiler warnings
97# -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
98# -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
99# lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
100# -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads)
101# -pthreads: Solaris/gcc
102# -mthreads: Mingw32/gcc, Lynx/gcc
103# -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
104#      doesn't hurt to check since this sometimes defines pthreads too;
105#      also defines -D_REENTRANT)
106# pthread: Linux, etcetera
107# --thread-safe: KAI C++
108# pthread-config: use pthread-config program (for GNU Pth library)
109
110case "${host_cpu}-${host_os}" in
111        *solaris*)
112
113        # On Solaris (at least, for some versions), libc contains stubbed
114        # (non-functional) versions of the pthreads routines, so link-based
115        # tests will erroneously succeed.  (We need to link with -pthread or
116        # -lpthread.)  (The stubs are missing pthread_cleanup_push, or rather
117        # a function called by this macro, so we could check for that, but
118        # who knows whether they'll stub that too in a future libc.)  So,
119        # we'll just look for -pthreads and -lpthread first:
120
121        acx_pthread_flags="-pthread -pthreads pthread -mt $acx_pthread_flags"
122        ;;
123
124        *freebsd*)
125        # freebsd 4 uses -pthread, freebsd 5 uses -lpthread
126        acx_pthread_flags="pthread -pthread"
127        ;;
128esac
129
130if test x"$acx_pthread_ok" = xno; then
131for flag in $acx_pthread_flags; do
132
133        case $flag in
134                none)
135                AC_MSG_CHECKING([whether pthreads work without any flags])
136                ;;
137
138                -*)
139                AC_MSG_CHECKING([whether pthreads work with $flag])
140                PTHREAD_CFLAGS="$flag"
141                ;;
142
143                pthread-config)
144                AC_CHECK_PROG(acx_pthread_config, pthread-config, yes, no)
145                if test x"$acx_pthread_config" = xno; then continue; fi
146                PTHREAD_CFLAGS="`pthread-config --cflags`"
147                PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
148                ;;
149
150                *)
151                AC_MSG_CHECKING([for the pthreads library -l$flag])
152                PTHREAD_LIBS="-l$flag"
153                ;;
154        esac
155
156        save_LIBS="$LIBS"
157        save_CFLAGS="$CFLAGS"
158        LIBS="$PTHREAD_LIBS $LIBS"
159        CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
160
161        # Check for various functions.  We must include pthread.h,
162        # since some functions may be macros.  (On the Sequent, we
163        # need a special flag -Kthread to make this header compile.)
164        # We check for pthread_join because it is in -lpthread on IRIX
165        # while pthread_create is in libc.  We check for pthread_attr_init
166        # due to DEC craziness with -lpthreads.  We check for
167        # pthread_cleanup_push because it is one of the few pthread
168        # functions on Solaris that doesn't have a non-functional libc stub.
169        # We try pthread_create on general principles.
170        AC_TRY_LINK([#include <pthread.h>],
171                    [pthread_t th; pthread_join(th, 0);
172                     pthread_attr_init(0); pthread_cleanup_push(0, 0);
173                     pthread_create(0,0,0,0); pthread_cleanup_pop(0); ],
174                    [acx_pthread_ok=yes])
175
176        LIBS="$save_LIBS"
177        CFLAGS="$save_CFLAGS"
178
179        AC_MSG_RESULT($acx_pthread_ok)
180        if test "x$acx_pthread_ok" = xyes; then
181                break;
182        fi
183
184        PTHREAD_LIBS=""
185        PTHREAD_CFLAGS=""
186done
187fi
188
189# Various other checks:
190if test "x$acx_pthread_ok" = xyes; then
191        save_LIBS="$LIBS"
192        LIBS="$PTHREAD_LIBS $LIBS"
193        save_CFLAGS="$CFLAGS"
194        CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
195
196        # Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
197        AC_MSG_CHECKING([for joinable pthread attribute])
198        attr_name=unknown
199        for attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
200            AC_TRY_LINK([#include <pthread.h>], [int attr=$attr;],
201                        [attr_name=$attr; break])
202        done
203        AC_MSG_RESULT($attr_name)
204        if test "$attr_name" != PTHREAD_CREATE_JOINABLE; then
205            AC_DEFINE_UNQUOTED(PTHREAD_CREATE_JOINABLE, $attr_name,
206                               [Define to necessary symbol if this constant
207                                uses a non-standard name on your system.])
208        fi
209
210        AC_MSG_CHECKING([if more special flags are required for pthreads])
211        flag=no
212        case "${host_cpu}-${host_os}" in
213            *-aix* | *-freebsd* | *-darwin*) flag="-D_THREAD_SAFE";;
214            *solaris* | *-osf* | *-hpux*) flag="-D_REENTRANT";;
215        esac
216        AC_MSG_RESULT(${flag})
217        if test "x$flag" != xno; then
218            PTHREAD_CFLAGS="$flag $PTHREAD_CFLAGS"
219        fi
220
221        LIBS="$save_LIBS"
222        CFLAGS="$save_CFLAGS"
223
224fi
225
226AC_SUBST(PTHREAD_LIBS)
227AC_SUBST(PTHREAD_CFLAGS)
228
229# Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
230if test x"$acx_pthread_ok" = xyes; then
231        ifelse([$1],,AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.]),[$1])
232        :
233else
234        acx_pthread_ok=no
235        $2
236fi
237AC_LANG_RESTORE
238])dnl ACX_PTHREAD
Note: See TracBrowser for help on using the repository browser.